XL 2021 Combien de mois dans une colonne

[Caninge]

Bonjour à tous,

je n'arrive pas à trouver la solution à mon problème.
je voudrais calculer le nombre de mois qui apparaissent dans une colonne.
Il faudrait peut-être voir avec les formats de cellule, je ne sais pas.
Avez-vous une idée ? Je pense que oui et vous remercie.
CANINGE

 

[vgendron]

bonjour
Regarde la fonction "Unique" qui est normalement disponible sur la version 2021
je dis normalement parce que chez moi. (2021), je ne l'ai pas... jamais compris pourquoi

 

[Caninge]

Bonjour,
tu veux dire le format de cellule - date ?

 

[vgendron]

ou alors avec une colonne intermédiaire pour avoir le mois

 

[vgendron]

Bonjour,
tu veux dire le format de cellule - date ?

non.. je veux dire la fonction "Unique"...
j'ai jamais parlé de format de cellule...??..

 

[ALS35]

Bonjour à tous,
Comme dit par vgendron, essaie :

=LET(c;B3:B14;NB(UNIQUE(SI(c="";"";MOIS(c)))))

Cordialement

 

[TooFatBoy]

Bonjour,

Il faudrait peut-être voir avec les formats de cellule, je ne sais pas.

C'est peu probable car le format de cellule sert seulement à modifier l'apparence du contenu d'une cellule, mais ne modifie pas ledit contenu.

 

[JHA]

Bonjour à tous,

Peut-être avec fréquence.
Par ligne

=SOMME(SI(FREQUENCE(SI(MOD(COLONNE($B3:$R3);2)=0;EQUIV(MOIS($B3:$R3);MOIS($B3:$R3);0));COLONNE($B3:$R3)-1);1))

Par colonne

=SOMME(SI(FREQUENCE(SI(MOIS(B$3:B$14);EQUIV(MOIS(B$3:B$14);MOIS(B$3:B$14);0));LIGNE($A$3:$A$14)-LIGNE($A$2));1))

JHA

 

[patricktoulon]

bonjour
ben ça dépend de ce que tu interprète dans mois différent
janvier-2025 et janvier-2024 sont deux mois différent ou c'est juste l'index ou nom du mois qui compte

 

[Caninge]

Bonjour à tous,
comme je dois partir bientôt, je regarderai vos réponses plus tard.
Je vous remercie. Bon après midi
Caninge

 

[Jean-Eric]

Bonjour,
Pour la question initiale !...

B16 : =NBVAL(UNIQUE(TEXTE($B$3:$B$14; "mm")))
B18 : =NBVAL(UNIQUE(TEXTE($B$3:$B$14; "aaaa-mm")))

Cdlt.

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @Caninge
En prenant en compte la remarque de @patricktoulon et avec les possibilités d'Excel2021 (solutions plus simples avec 2024 et 365)

Si c'est pour la totalité du tableau ($B$3:$S$14)

La liste des mois différents en $W$3 s'obtient par (sous forme de dates) :​

=CNUM(UNIQUE(TEXTE(TRIER(LET(dates;CNUM(FRACTIONNER.TEXTE(JOINDRE.TEXTE(";";VRAI;$B$3:$S$14);;";"));
                             FILTRE(dates;dates>DATEVAL("1/1/1980")))
                        );
                   "mmm-aa")
            )
      )

(>1/1/1980) pour éliminer les valeurs numériques des colonnes impaires)​

leur nombre par​

 =Nb($W$3#)

Si c'est pour chaque colonne individuellement:

=NBVAL(UNIQUE(TEXTE($B$3:$B$14;"mmm-aa")))

à copier sous chaque colonne (cf la 2ème formule de @Jean-Eric )​

Voir la pièce jointe
À bientôt

 

[job75]

Bonjour à tous,

Formule matricielle en B16 à tirer vers la droite :

=SOMME(--ESTNUM(EQUIV(LIGNE(INDIRECT("1:12"));MOIS(B3:B14);0)))

Sur Excel 2021 je pense que la validation par Ctrl+Maj+Entrée n'est pas nécessaire.

A+

 

[AtTheOne]

re

Sur Excel 2021 je pense que la validation par Ctrl+Maj+Entrée n'est pas nécessaire.

Bonjour @job75
Effectivement pas de validation matricielle avec EXCEL 2021, mais quand on rouvre le fichier avec une version antérieure les {} fleurissent un peu partout ...
À bientôt

 

[job75]

Sur les versions antérieures la validation par Ctrl+Maj+Entrée est indispensable, SOMMEPROD ne suffit pas.