combien de jours avant la date anniversaire

[hurricane]

bonjour

ptit question:

comment calculer le nombre de jours qu'il reste avant un anniversaire en ayant :
1 la date de naisssance
2 sans utiliser la fonction datedif

comme je suis un peu sec je fais appel au forum, pense que les filles elles se reconnaîtont vont faire un malheur sur cette petite formule.

@+

 

[Pascal76]

Salut

Je ne suis pas une fille donc je ne vais pas faire de malheur (LOL)

Imaginons que tu es ta date anniversaire en A1

La formule =A1-AUJOURDHUI() dans une cellule au format nombre te donne le nombre de jour jusqu'à la date.

Bon courage

Pascal

 

[hurricane]

salut pascal76

non pourt etre plus precis je prends un exemple

en A1 ma date de naissance : 23/03/1971
en A2: reponse anniversaire dans 353 jours

voila je pense que maintenant s'est plus clair.

@+

 

[Monique]

Bonjour,

C'est fait, dans les classeur "Dates et Heures"
<http://www.excel-downloads.com/html/French/fichiers/programmation-date_maj-1.htm>

La formule de classement des fêtes est la plus facile à adapter.
Les dates de naissance en colonne B
Nombre de jours avant l'anniversaire :
=DATE(ANNEE(AUJOURDHUI())+SI(OU(MOIS(B2)<MOIS(AUJOURDHUI());ET(MOIS(B2)<=MOIS(AUJOURDHUI());JOUR(B2)<JOUR(AUJOURDHUI())));1);MOIS(B2);JOUR(B2))-AUJOURDHUI()
Pour raccourcir, tu peux taper =AUJOURDHUI() en H1 par exemple
=DATE(ANNEE(H$1)+SI(OU(MOIS(B2)<MOIS(H$1);ET(MOIS(B2)<=MOIS(H$1);JOUR(B2)<JOUR(H$1)));1);MOIS(B2);JOUR(B2))-H$1

 

[pascal liberty]

bonjour

si C4 est la date de naissance voici une formule:

=SI((DATEVAL(JOUR(C4)&"/"&MOIS(C4)&"/"&ANNEE(AUJOURDHUI())))-AUJOURDHUI()<0;(DATEVAL(JOUR(C4)&"/"&MOIS(C4)&"/"&ANNEE(AUJOURDHUI())+1))-AUJOURDHUI();(DATEVAL(JOUR(C4)&"/"&MOIS(C4)&"/"&ANNEE(AUJOURDHUI())))-AUJOURDHUI())

Pascal liberty

 

[hurricane]

salut pascal liberty monique

merci pour la formule, j'avais une solution avec datedif mais sans j'etais resté coincé

=(AUJOURDHUI()+365)-DATEDIF(D8;AUJOURDHUI();"yd")-AUJOURDHUI()

merci encore

@+

 

[Pascal76]

Salut

essaies ceci

=SI((JOUR(A1) & "/" & MOIS(A1) & "/" & ANNEE(AUJOURDHUI()))-AUJOURDHUI()>0;(JOUR(A1) & "/" & MOIS(A1) & "/" & ANNEE(AUJOURDHUI()))-AUJOURDHUI();(JOUR(A1) & "/" & MOIS(A1) & "/" & ANNEE(AUJOURDHUI())+1)-AUJOURDHUI())

Bon courage

Pascal

 

[hurricane]

merci aussi pascal 76

@+