XL 2016 Chercher un mot par la droite

[Maxinet]

Bonjour à tous,
Je cherche un moyen d'extraire un mot dans une chaine de caractère, en partant de la droite, et lui attribuer un résultat en fonction d'une table...
Pour moi c'est un vrai casse tête car le mot peut être présent au début ou au milieu mais il ne faut pas en tenir compte... car seule la fin de la chaine de caractère doit être exploitée...
Je fais appel à un pro de la formule excel, qui pourrait m'aider à trouver une solution
Bonne soirée à tous !

 

[gbinforme]

Bonjour,
Voilà ta formule

 

[job75]

Bonsoir Maxinet, gbinforme,

Formule matricielle en B3 :

=RECHERCHEV(STXT(A3;MAX(SIERREUR(CHERCHE(E$3:E$5;A3);0));MIN(G:G))&"*";E:F;2;0)

à valider par Ctrl+Maj+Entrée et tirer vers le bas.

A+

 

[Maxinet]

Bonjour,
Voilà ta formule

Bonsoir gbinforme, je me suis doute mal exprimé, mais la formule devait aller voir si elle trouvait une valeur de la table dans la colonne A (rouge, vert...), en partant de la droite, elle devait mettre la correspondance (OUI, NON, ATTENTE). Ce que tu proposes fait l'inverse
Merci quand même, c'est toujours bien d'avoir des exemples de formules !

 

[Maxinet]

Bonsoir Maxinet, gbinforme,

Formule matricielle en B3 :

=RECHERCHEV(STXT(A3;MAX(SIERREUR(CHERCHE(E$3:E$5;A3);0));MIN(G:G))&"*";E:F;2;0)

à valider par Ctrl+Maj+Entrée et tirer vers le bas.

A+

Bonsoir job75, ouah c'est exactement ce que je cherchais... trop fort ! Je vais décortiquer la formule pour la comprendre, mais là c'est top !
Merci beaucoup !!

 

[crocrocro]

Bonjour à tous et bravo à Job75
La formule pouvait être écrire sans avoir à utiliser la colonne supplémentaire G en remplaçant simplement Min(G:G) par MIN(NBCAR(E$3:E$5)).
Elle n'en aurait été que plus belle !

=RECHERCHEV(STXT(A3;MAX(SIERREUR(CHERCHE(E$3:E$5;A3);0));MIN(NBCAR(E$3:E$5)))&"*";E:F;2;0)

 

[job75]

Bonjour crocrocro,

Tout à fait, merci, puisque la formule est matricielle autant en profiter.

A+

 

[Maxinet]

Bonsoir Crocrocro, je suis d'accord, c'est une très belle formule !! Fallait la trouver celle la
Encore merci !

 

[DJunqueira]

Une autre contribution à la formule.

=RECHERCHEV(STXT(A3;AGREGAT(14;6;CHERCHE(E$3:E$5;A3);1);MIN(G:G))&"*";E:F;2;0)

 

[mapomme]

Bonsoir à tous,

Comme j'avais commencé, je publie.Une formule matricielle dont le principe est analogue aux formules précédente. J'espère qu'elle fonctionnera sur les versions d'Excel antérieures à O365 (je ne peux pas vérifier car je n'ai plus d'autre version à ma disposition).
=INDEX(F$3:F$5;EQUIV(MAX(SIERREUR(CHERCHE(E$3:E$5;A3);""));SIERREUR(CHERCHE(E$3:E$5;A3);"");0))

 

[job75]

Bonjour à tous,

La formule de mapomme est la meilleure car elle n'utilise pas une partie des textes en E3:E5.

A+