XL 2019 Calendrier automatique

fanch55

XLDnaute Barbatruc

• 2 Mai 2020

• #2

Salut,
Je suppose que c'est celle qui est dans le module 1 :

VB:

Sub Masquer_Jour()
Dim Cell As Range
    For Each Cell In [E7:AI7]
        Columns(Cell.Column).Hidden = Month(Cell) <> [C1]
    Next
'   Range("B6:AF13").ClearContents <== pas compris
End Sub

Attention à ta liste pour le combobox des mois, tu as du effacer des lignes dans la feuille

 

Vote positif 0 Vote négatif

T

Thomas19

XLDnaute Nouveau

• 2 Mai 2020

• #3

Super, ça marche maintenant. Merci beaucoup

 

Vote positif 0 Vote négatif

Saalut

XLDnaute Junior

• 2 Mai 2020

• #4

Bonjour ,
pour supprimer les deux jours dans le mois de février ; il faut cette formule
=SI(D7="";"";SI(MOIS(D7+1)=$C$1;D7+1;""))
Bonne continuation .

 

Pièces jointes

• Calendrier - 5 (1)résolu.xlsm

  52.1 KB · Affichages: 8

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 2 Mai 2020

• #5

Oki, ça fonctionne, c'est évident, mais ce n'était pas la demande.

• Par macro
• Enlever les colonnes, pas les blanchir ...

Mais je chipote ...

 

Vote positif 0 Vote négatif

T

Thomas19

XLDnaute Nouveau

• 2 Mai 2020

• #6

Merci pour votre aide
J'ai fait les modifs, et oui, par macro
Le problème est que ça ne fonctionne pas pour l'onglet "Réunion de production" --> Module 2
J'ai essayé dans tous les sens mais je n'y arrive pas..
Pouvez-vous m'aider?
Merci d'avance

 

Pièces jointes

• Calendrier - 6.xlsm

  52.2 KB · Affichages: 22

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 2 Mai 2020

• #7

C'est normal, vous avez changé la cellule de référence.
Ci-dessous une sub qui "s'adapte":

VB:

Sub Masquer_JourRéunionProd()
Dim Cell        As Range
Dim Target      As Range
Dim Num_Mois    As Integer

Set Target = [AH7:AK7]

    Num_Mois = Range(ActiveSheet.Shapes(Application.Caller).OLEFormat.Object.LinkedCell).Value
    Target.Columns.Hidden = False
    For Each Cell In Target
        Columns(Cell.Column).Hidden = Month(Cell) <> Num_Mois
    Next

Set Target = Nothing
End Sub

 

Vote positif 0 Vote négatif

T

Thomas19

XLDnaute Nouveau

• 2 Mai 2020

• #8

ça fonctionne, trop bien!!
tu as fait ma soirée, merci beaucoup!!
il me reste plus qu'à essayer de comprendre..
Bonne soirée

 

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 2 Mai 2020

• #9

Ce n'est pas la peine de faire plusieurs modules pour la même opération sur des onglets différents :

Tu mets cette sub dans un module quelconque :

VB:

Public Sub Masquer_Jour_En_Trop(Plage As String)
Dim Cell        As Range
Dim Target      As Range
Dim Num_Mois    As Integer

Set Target = Range(Plage) ' Plage de cellules où sont les dates

   ' On récupère le numéro de mois dans la cellule associée à la Shape Appelante ( mois traité )
    Num_Mois = Range(ActiveSheet.Shapes(Application.Caller).OLEFormat.Object.LinkedCell).Value

  ' On rend visible toutes les dates qui ont pu être masquées précédemment
    Target.Columns.Hidden = False

  ' On inspecte chaque cellule de la plage cible
    For Each Cell In Target
      ' si le numéro de mois de la cellule cible est différent du numéro de mois traité,
     '  la colonne de cette cellule doit être masquée
        Columns(Cell.Column).Hidden = Month(Cell) <> Num_Mois
    Next

' On libère la mémoire
Set Target = Nothing
End Sub

Puis sur les combobox de tes feuilles , tu affectes la macro ainsi :

'Masquer_Jour_En_Trop "F7:AJ7"'

Cliquez pour agrandir...

F7:AJ7 représente la plage où sont tes jours ( lundi 1, mardi 2 etc...)
La plage entre Double Quote ( " ), le tout entre simple cote ( ' ) .

Voili voilou, c'est pas sorcier ..

 

Vote positif 0 Vote négatif

Solution

T

Thomas19

XLDnaute Nouveau

• 3 Mai 2020

• #10

Au top!!
Merci

 

Vote positif 0 Vote négatif