Microsoft 365 Calculer un total selon une date occurrente

Jojo973 · 11 Mai 2024

Bonjour la communauté, voici ma problématique :
J'ai un tableau avec des dates occurrentes qui ont des valeurs associées et qui devront être récupérées et additionnées pour en faire une somme sur une seule ligne :

Je précise que l'exemple est très simplifié par rapport au fichier de travail.
J'ai essayé avec des boucles sur ce principe là :

je prends la première date et je vérifie s'il y a une valeur dans la colonne "Vert"
si oui, je la mets dans une variable val_vert
je passe à la ligne suivante et je teste à nouveau et j'implémente val_vert
etc...

Cela fonctionne bien pour une date mais je n'arrive pas à instancier la deuxième date.
J'ai joint un fichier sans code car franchement je suis embrouillé et j'ai besoin de quelque chose de propre.

Merci pour votre aide.

JHA · 11 Mai 2024

Bonjour à tous,

Peut-être avec une formule:

VB:

=SOMMEPROD(($K6=$D$6:$D$11)*(L$5=$E$5:$F$5);$E$6:$F$11)

JHA

JHA · 11 Mai 2024

Bonjour à tous,

En 2 clic avec Power Query

JHA

danielco · 11 Mai 2024

Bonjour,

Avec deux formules :
1. en K6 :

VB:

=PIVOTER.PAR(D6:D11;;E6:E11;SOMME;;0)

2. en M6 :

Code:

=EXCLURE(GROUPER.PAR(D6:D11;F6:F11;SOMME;;0);;1)

Daniel

mapomme · 11 Mai 2024

Bonsoir à tous ,

Avec des formules classiques :

En K1 une formule matricielle à valider par la combinaison des 3 touches Ctrl+Maj+Entrée.
En L1 une formule ordinaire.
En M1 une autre formule ordinaire.

Puis copier les formules de K1 à M1 vers le bas jusqu'à obtenir des cellules vides.

job75 · 11 Mai 2024

Bonjour à tous,

Formule matricielle en K6 :

Code:

=SIERREUR(PETITE.VALEUR(SI(NON(NB.SI(K$5:K5;D$6:D$11));D$6:D$11);1);"")

Formule en L6 à tirer sur M6 :

Code:

=SOMME.SI($D:$D;$K6;E:E)

Les valeurs zéro sont masquées (Options avancées).

A+

mapomme · 11 Mai 2024

danielco à dit:
Avec deux formules :
1. en K6 :

VB:

=PIVOTER.PAR(D6:D11;;E6:E11;SOMME;;0)

2. en M6 :

Code:

=EXCLURE(GROUPER.PAR(D6:D11;F6:F11;SOMME;;0);;1)

Bonsoir @danielco ,

A quel canal es-tu inscrit pour disposer des fonctions PIVOTER.PAR et GROUPER.PAR ?
Je suis inscrit au canal actuel (aperçu) et je n'en dispose pas .

danielco · 11 Mai 2024

Bonjour à tous,

@ mapomme : Je suis inscrit au canal beta. Donc ces fonctions sont toujours en beta. C'est l'inconvénient, on ne sait jamais quand les fonctions sont généralisées...

Daniel

danielco · 11 Mai 2024

Avec Excel 365 standard :
en K6 :

VB:

=UNIQUE(D6:D11)

En L6, à tirer vers la droite :

Code:

=BYROW($K6#;LAMBDA(x;SOMME(FILTRE(E6:E11;$D$6:$D$11=x))))

Daniel

Jojo973 · 18 Mai 2024

Bonjour, merci pour toutes les réponses, j'ai pu trouver mon bonheur !

Désolé pour la réponse tardive

Microsoft 365 Calculer un total selon une date occurrente

Jojo973

XLDnaute Occasionnel

Pièces jointes

JHA

XLDnaute Barbatruc

Pièces jointes

JHA

XLDnaute Barbatruc

Pièces jointes

danielco

XLDnaute Accro

Pièces jointes

mapomme

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

mapomme

XLDnaute Barbatruc

danielco

XLDnaute Accro

danielco

XLDnaute Accro

Jojo973

XLDnaute Occasionnel

Discussions similaires