calculer le nombre de mois à partir de dates

[jem]

Bonsoir à tous,

Voici mon souci,
je souhaiterais renseigner automatiquement la colonne "nombre" automatiquement qui dépend des mois, en fonction du nombre de mois évoqué dans un tableau.

Je vous joins un exemple plus compréhensible.

Merci

JEM

 

[jem]

Re : calculer le nombre de mois à partir de dates

re,

voici le fichier joint avec l'exemple.

Merci

jem

 

[JeanMarie]

Re : calculer le nombre de mois à partir de dates

Re...

Pour répondre à tes dernières question, essaye cette formule

=SOMME(SI(($B$1:$B$3000="soldée")*($C$1:$C$3000<>"");MOIS($C$1:$C$3000)=COLONNE(A1))*1)

à valider par les trois touches, et à glisser vers la droite.

On peut aussi l'écrire de cette manière

=SOMME(SI($B$1:$B$3000="soldée";SI($C$1:$C$3000<>"";MOIS($C$1:$C$3000)=COLONNE(D1)))*1)

@+Jean-Marie

 

[Monique]

Re : calculer le nombre de mois à partir de dates

Bonjour tous,

Ou bien celle-ci, à valider simplement par "Entrée"
en mettant un accent en août, décembre et aussi en février
=SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B183="soldée"))

Ou bien ces deux-ci, à valider pat ctrl, maj et entrée :
=SOMME(SI($B1:$B183="soldée";MOIS($C1:$C183)=COLONNES($F4:F4))*1)

=SOMME(SI($B1:$B183="soldée";MOIS($C1:$C183)=COLONNE()-5)*1)

 

[jem]

Re : calculer le nombre de mois à partir de dates

Merci JeanMarie et Monique pour vos solutions,

Je les ai toutes essayées. elles marchent bien, mais je ne comprends pas trop les formules

La 2eme formule de JeanMarie, je lai comprise, la première un peu moins, c'est la multiplication dans la formule qui me trouble !

La 1ere formule de Monique, je ne l'ai pas comprise, à quoi correspond "mmmm", au mois?
pour la 2nde formule de Monique , le $F4:F4 ca doit correspondre à quoi exactement?
et pour la 3eme, COLONNE()-5, ca correspond à quoi?

je vous remercie pour vos réponses, je ne m'en sortirais pas sans vous, grand et mille merci

JEM

 

[Monique]

Re : calculer le nombre de mois à partir de dates

Re,

Tes mois sont sous forme de texte, en ligne 1 et sous forme de nombre en colonne C
=TEXTE(C1;"mmmm")=I1 renvoie VRAI

=TEXTE("23/4/08";"mmmm") renvoie avril, par exemple

=SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B183="soldée"))
revient à avoir les dates, en C1:C183, sous forme de mois en texte

Colonnes($F4:F4) donne le nb de colonnes qu'il y a entre F4 et… F4, soit 1
Recopiée vers la droite, ça devient Colonnes($F4:G4) et ça renvoie 2 etc

Colonne()-5, je n'aime pas
=COLONNE() renvoie le n° de la colonne où la formule est saisie.
6 pour la colonne F, 7 pour G etc
Ton tableau démarre en colonne F, on veut 1 parce que janvier,
donc, en colonne F, on met Colonne()-5 pour avoir 1
Recopié vers la droite, ça donne 7-5 puis 8-5 etc
Je n'aime pas parce que, si on insère ou si on supprime une colonne à gauche, Colonne() change de résultat

 

[jem]

Re : calculer le nombre de mois à partir de dates

je te remercie pour tes explications, c'est plus clair maintenant. j'espère que les formules marcheront sur mon fichier demain, je croise les doigts

Merci encore

JEM

 

[jem]

Re : calculer le nombre de mois à partir de dates

Bonsoir,

J'ai modifié légérement la formule:

=SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B18 3="soldée"))

en

=SI($A$1:$A$183="Travail";SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B183="soldée")))

je voudrais quand dans la colonne A il y a le mot Travail, alors faire le calcul du nombre de "travail" soldée , et ensuite, je déduis ce résultat du nombre d'actions soldées.

Je joins un fichier.

MERCI

jem

 

[jem]

Re : calculer le nombre de mois à partir de dates

Bonsoir à tous,

J'ai trouvé la solution à mon problème:

=SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B183="soldée")*($A1:$A183="Travail"))
pour calculer le nombre de "travail" soldées, que je déduis de la formule
=SOMMEPROD((TEXTE($C1:$C183;"mmmm")=F$1)*($B1:$B183="soldée"))
pour avoir le nombre d'actionS soldées.

Bonne soirée à tous

JEM