XL 2019 Calcul Temps entre deux horaires

[lolo42]

Bonjour a tous,
je bute sur ma formule de calcul de temps horaire entre 2 heures données !

 

[sylvanu]

Bonjour Lolo,
Tel qu'exprimé en G et H, ils sont considérés par XL en décimal et non en sexadécimal.
Donc ramené à la notation hh,mm, on arrive à :

=SI(H4="";"";ENT(((ENT(H4)+100*(H4-ENT(H4))/60)-(ENT(G4)+100*(G4-ENT(G4))/60)))+60*(((ENT(H4)+100*(H4-ENT(H4))/60)-(ENT(G4)+100*(G4-ENT(G4))/60))-ENT(((ENT(H4)+100*(H4-ENT(H4))/60)-(ENT(G4)+100*(G4-ENT(G4))/60))))/100)

Ce serait quand même plus simple de mettre en notation horaire hh:mm, ce serait automatique.

 

[lolo42]

Très étonnée de la longueur de la formule, mais elle fonctionne a merveille!
Exactement ce que je voulais comme résultat.
N'y serait pas arrivé sans votre aide précieuse.
Merci beaucoup.
Cordialement

 

[sylvanu]

On doit pouvoir simplifier.
Mais il faut convertir 12,35 (hh,mm) en 12.58 en décimal, ça fait :

ENT(G4)+100*(G4-ENT(G4))/60

Idem pour 20,15.
Et il faut ramener le résultat décimal en notation hh,mm.

 

[TooFatBoy]

Bonjour,

Peut-être une autre possibilité (si ça fonctionne...) :

=ENT(24*(TEMPS(ENT(H4);100*MOD(H4;1);0)-TEMPS(ENT(G4);100*MOD(G4;1);0)))+MOD(24*(TEMPS(ENT(H4);100*MOD(H4;1);0)-TEMPS(ENT(G4);100*MOD(G4;1);0));1)*0,6

 

[TooFatBoy]

Tu as vraiment besoin de ce format bizarre, à mi-chemin entre des heures "normales" et des heures en centièmes ?

Est-ce pour simplifier la vie de la personne qui saisie les heures en question ?
(plus simple de saisir la "," que les ":")

 

[GALOUGALOU]

bonjour lolo 4 bonjour le fil
sans oublier que pour excel le format horaire c'est xx:xx:xx, et là le calcul est automatique. (comme le dit sylvanu)
pour s'en convaincre, dans une cellule il suffit de taper le raccourci clavier ctrl+: (horaire = maintenant)
cordialement
galougalou

 

[TooFatBoy]

Une formule plus courte :

=HEURE(SUBSTITUE(H4;",";":")-SUBSTITUE(G4;",";":"))+MINUTE(SUBSTITUE(H4;",";":")-SUBSTITUE(G4;",";":"))/100

 

[eriiic]

Bonjour,

D'autant plus qu'en saisissant au format excel on voit tout de suite l'erreur si on saisi 2:72
2,72 passe totalement inaperçu.
Il vaut mieux prendre de bonnes habitudes.
eric

 

[GALOUGALOU]

re le fil
en complément pour aider un collaborateur dans sa saisie, avec virgule ou avec point, une boite de dialogue qui valide au format horaire, n'importe où dans la feuille et dans la cellule active.
un code dans l'événement feuille sur double clic pour faire apparaitre la boite de dialogue.
cordialement
galougalou

 

[Modeste geedee]

Bonsour®

Une formule plus courte :

la mienne est plus courte que la votre !
=SUBSTITUE(TEXTE(TEXTE(100*H4;"00\:00")-TEXTE(100*G4;"00\:00");"h:mm");":";",")

Spoiler

Pour afficher ce contenu, nous aurons besoin de votre consentement pour définir des cookies tiers.
Pour plus d'informations, consultez notre page sur les cookies.

Accepter les cookies de tiers

 

[TooFatBoy]

Pour une fois que ce n'est pas moi qui ai la plus courte...