Calcul entre 2 dates

[LN1]

Bonjour à tous,

Je souhaiterai avoir une petite aide sur un calcul de jours entre 2 dates.

J'ai une commande qui doit être livrée par exemple le 14/06/07.
J'ai inscrit dans le tableau ci-joint 3 dates de livraison différentes pour calculer ensuite le nombre de jours entre la date de livraison prévue et la date de livraison réelle me permettant ensuite de voir si la commande a été livrée dans les temps, en avance ou en retard de x jours...
Seulement, en utilisant la fonction "Nb.jours. ouvres", j'obtiens des résultats "faussés" à 1 jour près.
😕

Pourriez-vous me dire si j'utilise la bonne fonction ?
Merci à tous et bon après-midi.

LN

 

[Staple1600]

Re : Calcul entre 2 dates

Bonjour


Peut-etre en utilisant la fonction DATEDIF
Voir ici: DATEDIF Function (anglophone)

Ce lien n'existe plus (francophone)

En provenance du forum
SOURCE:https://www.excel-downloads.com/threads/excel-quelques-fonctions-excel.34872/

Calculer le temps écoulé entre 2 dates ( en années , mois et jours )
Exemple pour calculer l'age d'une personne dont la date de naissance est saisi dans la cellule A1
=DATEDIF(A1;AUJOURDHUI();'y')&' ans , '&DATEDIF(A1;AUJOURDHUI();'Ym')&' mois et '&DATEDIF(A1;AUJOURDHUI();'Md')&' jours'


Vérifier si la date saisie dans la cellule A1 correspond au jour anniversaire (Aujourdui )
=SI(ET(DATEDIF(A1;AUJOURDHUI();'ym')=0;DATEDIF(A1; AUJOURDHUI();'md')=0);'Oui';'Non')


Afficher la moyenne du temps passé en mm : ss , avec en A1 le temps total en secondes et en A2 le nb d'occurrences
=A1/24/60/60/A2
La cellule contenant la formule doit etre au format [mm] : ss

 

[Monique]

Re : Calcul entre 2 dates

Bonjour,

Fais un essai comme ça :
=NB.JOURS.OUVRES(A4;B4;$G$4:$G$10)-(B4>=A4)+(B4<A4)

Ou bien (pas besoin de cocher l'utilitaire d'analyse) :
=(SOMMEPROD((JOURSEM(LIGNE(INDIRECT(A4&":"&B4));2)<6)*(NB.SI(Fer;LIGNE(INDIRECT(A4&":"&B4)))=0))-1)*SI(A4>B4;-1;1)

 

[LN1]

Re : Calcul entre 2 dates

Merci à tous les 2 pour votre aide. C'est nickel !!

Cependant juste pour comprendre la formule de Monique serait-il possible de me dire à quoi correspond la dernière partie de la formule : -(B4>=A4)+(B4<A4) ?


Bonne journée à tous !

 

[Monique]

Re : Calcul entre 2 dates

Bonjour,

La fonction Nb.Jours.Ouvres prend en compte le jour de début et le jour de fin.
Elle renvoie 1 quand début et fin sont égaux

= - (B4>=A4)+(B4<A4)
Chaque partie de la formule renvoie VRAI ou FAUX donc 0 ou 1
- VRAI + VRAI = 0
- VRAI + FAUX = - 1
- FAUX + VRAI = 1
- FAUX + FAUX = 0

 

[LN1]

Re : Calcul entre 2 dates

Merci pour ces précisions, ça me sera utile pour une prochaine fois !

Bon aprem' à tous !