barre d'outils et bouton de commande

[vincent50]

bonjour, comment faire pour affecter un bouton de commande perso à une macro dans un classeur et à une autre macro dans un autre classeur?
Peut on creer une barre d'outil qui s'ouvre et qui se ferme avec le classeur?

 

[skoobi]

Re : barre d'outils et bouton de commande

Bonjour,

voici 2 codes à placer dans "ThisWorkbook".
Le premier code cré "ma macro" dans le menu outils à l'ouverture du fichier et le second enlève "ma macro" à la fermeture du fichier:

Private Sub Workbook_Open()
    Dim ToolsMenu As CommandBarPopup
    Dim NewMenuItem As CommandBarButton
    Set ToolsMenu = Application.CommandBars(1).FindControl(Type:=10, ID:=30007)
    Set NewMenuItem = ToolsMenu.Controls.Add(Type:=1, Temporary:=True)
    With NewMenuItem
        .Caption = "ma macro"
        .OnAction = "macro1"
    End With
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars(1).FindControl(Type:=10, ID:=30007).Controls("ma macro").Delete
    On Error GoTo 0
End Sub

La macro s'appelle ici "macro1" qui doit se trouver dans un module.

 

[vincent50]

Re : barre d'outils et bouton de commande

bonjour, merci pour ta reponse, ca marche super, sauf que mon bouton apparait dans le menu "outils" et j'aimerai si possible qu'il apparaisse dans un nouveau menu "perso".
Est ce possible?

 

[skoobi]

Re : barre d'outils et bouton de commande

Bonjour,

voici:

Private Sub Workbook_Open()
    Dim MenuPerso As CommandBarPopup
    Dim NewMenuItem As CommandBarButton
    Set MenuPerso = Application.CommandBars(1).Controls.Add(Type:=10, Temporary:=True)
    MenuPerso.Caption = "perso"
    Set NewMenuItem = MenuPerso.Controls.Add(Type:=1, Temporary:=True)
    With NewMenuItem
        .Caption = "ma macro"
        .OnAction = "macro1"
    End With
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars(1).Controls("perso").Delete
    On Error GoTo 0
End Sub

Bonne après-midi.

 

[vincent50]

Re : barre d'outils et bouton de commande

Merci de ta reponse rapide, c'est exactement ce qu'il me fallais.

 

[vincent50]

Re : barre d'outils et bouton de commande

Encore une petite chose, comment fait on pour mettre plusieurs boutons de commande dans ce menu car j'ai essayé d'en mettre un deuxieme mais il ne m'affiche que le dernier enregistré, ca n'affiche pas les autres.

 

[skoobi]

Re : barre d'outils et bouton de commande

Tu ajoutes ceci à la fin de la première macro:

    Set NewMenuItem2 = MenuPerso.Controls.Add(Type:=1, Temporary:=True)
    With NewMenuItem2
        .Caption = "ma macro2"
        .OnAction = "macro2"
    End With

 

[vincent50]

Re : barre d'outils et bouton de commande

merci, j'avais trouver entre temps, en fait j'avais oublié de copier la ligne "set newmenuitem ....".
Encore merci de ton aide.

 

[Pyrof]

Re : barre d'outils et bouton de commande

Bonjour,

Voici une méthode assez simple de pouvoir créer ces propres menus