auto_open sous ppt

[phestaca]

Bonjour,

j'ai un petit probleme.
J'ai créé un auto-open pour ppt en macro complémentaire et ca marche tres bien, trop bien meme car il n'attend pas que le document s'ouvre.
En effet, ppt s'ouvre, auto open s'exécute PUIS la présentation s'ouvre ... et donc la est mon probleme ... car je veux faire des manips sur la presentation a l'ouverture (version ppt 2002) ...

quelqu'un a une idée pour dire "attendre que ca s'ouvre" ...

Merci beaucoup

 

[PMO2]

Re : auto_open sous ppt

Bonjour,

En m'inspirant d'une réponse similaire que j'ai précédemment fait paraître,

MARCHE A SUIVRE
1) ouvrez un nouveau PowerPoint
2) Dans un module standard, copiez le code suivant:

Public ppApplication As New ClsEvents
Sub Auto_Open()
Set ppApplication.ppApp = Application
End Sub
Sub Auto_Close()
Set ppApplication.ppApp = Nothing
End Sub

3) Créez un module de classe, faites F4 et changez la propriété (Name) Classe1 par ClsEvents puis copiez le code suivant :

Public WithEvents ppApp As Application

Private Sub ppApp_PresentationClose(ByVal Pres As Presentation)
MsgBox "Au revoir et à la prochaine fois"
End Sub

Private Sub ppApp_PresentationOpen(ByVal Pres As Presentation)
'--- On identifie le fichier pour éviter d'effectuer le traitement sur TOUS les fichiers ---
If ActivePresentation.Name <> "phestaca.ppt" Then Exit Sub
'--- Exemple de traitement ---
With Application
  .WindowState = ppWindowNormal
  .Width = 92.25
  .Height = 25.5
  MsgBox "Pseudo traitement de " & .ActivePresentation.Name
  .WindowState = ppWindowMaximized
End With
End Sub

4) Dans PowerPoint, faites menu Fichier/Enregistrer sous… Type de fichier : Macro complémentaire PowerPoint (*.ppa) et cliquez sur Enregistrer
5) Faites menu Outils/Macros complémentaires… et dans la boîte Macros complémentaires cliquez sur Ajouter un nouveau
6) Sélectionnez la macro complémentaire .ppa qui vient d’être créée et cliquez sur OK
7) Fermez PowerPoint
8) Ouvrez le PowerPoint et, si tout s’est bien passé, vous devez y voir des évènements qui s’exécutent.

Je joins en exemple un.ppt et un .ppa . Ce dernier doit être placé dans le dossier Macros complémentaires dont le chemin, chez moi, est C:\Documents and Settings\Patrick\Application Data\Microsoft\Macros complémentaires (à adapter).

Cordialement.

PMO
Patrick Morange