Aide: intégration d'une vérification de similitude de caractères dans une formule

[UnknownUser]

Bonjour,

Je ne suis pas un grand pro d'Excel et j'ai récupéré aujourd'hui un fichier dans le cadre de mon boulot et j'aimerai l'adapter à mes besoins (la personne ayant créé l'excel n'est plus là :/).

Contexte:
Ce fichier sert à mesurer la performance d'un outil (avec le nombre d'utilisation) au jour le jour. Plusieurs feuilles existent: une Donnée_2015 contient au jour le jour le nombre d'utilisations (idem pour 2014 sur la feuille Données_2014).

Enfin, j'ai une feuille "récapitulatif" avec la possibilité de choisir une plage de date pour voir les performances ces jours-là.

Besoins:
Je souhaiterai également récupérer les données de 2014 pour ces mêmes jours afin de pouvoir établir un différentiel de perf (ex. 05/06/2015, l'outil a fait +20% de visites par rapport à 2014) dans une autre cellule.

J'ai ma formule pour récupérer ma donnée de 2015 qui est:
=SI($A15="";"";SOMME.SI(Donnees_2015!$C$4:$C$368;"="&$A15;Donnees_2015!$D$4:$D$368))

A15: étant ici ma colonne avec le jour (ex. 01/08/2015) de ma feuille en cours
C4:C368 étant la liste des jours de la feuille Données 2015 (du 1er janvier au 31 Décembre)
D4368 étant la performance de l'outil chaque jour.

Question:
J'aimerai donc récupérer les données 2014. Je ne peux pas utiliser la même fonction en changeant juste la feuille appelée (Données_2014 au lieu de Données_2015) car dans ma fonction, je fais appel la colonne "A" qui contient pour la date: XX/XX/2015. Dans ma feuille Données_2014, ma date est au format XX/XX/2014.

Malheureusement je dois conserver le format de ma date avec l'année.

Donc idéalement, j'aimerai intégrer dans mon calcul au niveau du SI" la condition suivante:
 si les 5 premiers caractères des cellules de ma colonne A -- disons A15-- (ce qui correspond à XX/XX -- ex. 12/01)) de ma feuille en cours sont équivalent aux 5 premiers caractères de la colonne A15 de la feuille Données 2014... [le reste de la fonction ne change pas].

J'espère avoir été clair (je n'en suis pas sur :/).
Merci par avance

 

[Modeste]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Bonjour UnknownUser et bienvenue à toi

S'il s'agit de vraies dates, tu ne peux sans doute pas comparer les 5 caractères de gauche de tes deux cellules. Par contre, tu peux vraisemblablement t'assurer que le jour et le mois sont identiques, avec quelque chose comme:

=ET(JOUR(Données_2014!A15)=JOUR(Données_2015!A15);MOIS(Données_2014!A15)=MOIS(Données_2014!A15))

ou

=Données_2015!A15=DATE(ANNEE(Données_2014!A15)+1;MOIS(Données_2014!A15);JOUR(Données_2014!A15))

Ceci étant, on pourrait sans doute faire des propositions bien plus précises, si on disposait d'un extrait (sans données confidentielles) de ton fichier (ou de quelque chose qui y ressemblerait )

 

[UnknownUser]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Merci de ces premiers éléments de réponses.
J'ai mis en jaune la colonne où j'aimerai implémenter le calcul.


Voici un extrait de mon fichier

 

[Modeste]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Re-bonjour,

Dans tes différentes feuilles, les dates n'apparaissent chacune qu'une seule fois? L'utilisation de SOMME.SI donnerait à penser qu'il pourrait y avoir des doublons.
S'il n'y a pas de doublons (et si j'ai bien compris!!) essaie, en C14 de ton tableau de bord:

=SI(A14="";"";INDEX(Donnees_2014!$D$4:$D$368;EQUIV(DATE(ANNEE(A14)-1;MOIS(A14);JOUR(A14));Donnees_2014!$C$4:$C$368;0)))

 

[UnknownUser]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Alors d'abord merci de ton temps.

Tu as en effet tout compris, ça marche nickel.

J'aurai une dernière petite faveur, peux tu m'expliquer ce que fait la formule.

Et encore un grand merci!

 

[Modeste]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

J'aurai une dernière petite faveur, peux tu m'expliquer ce que fait la formule

Ouaahh eh non, hein Faut pas abuser: on n'est pas sur un forum d'entraide, que diable! Quoi! ... Si, justement!? ... Au temps pour moi, alors!

DATE(ANNEE(A14)-1;MOIS(A14);JOUR(A14))

La date en A14 étant 01/01/2015, cette partie de la formule crée une nouvelle date ayant le même jour, le même mois ... un an plus tôt (soit, le 01/01/2014 ... enfin il me semble )

EQUIV(cette_nouvelle_date;Donnees_2014!$C$4:$C$368;0)

donne la position de la date en question, dans la plage concernée en colonne C de la feuille de 2014

INDEX(Donnees_2014!$D$4:$D$368;la_position_donnée_ci-dessus)

renvoie la valeur, dans la plage de D4 à D368 de la feuille 2014, à la position fournie par EQUIV

Le SI en début de formule, permet de ne rien afficher, si aucune date n'est inscrite en A14.
On pourrait améliorer d'un chouïa en utilisant

=SIERREUR(INDEX(Donnees_2014!$D$4:$D$368;EQUIV(DATE(ANNEE(A14)-1;MOIS(A14);JOUR(A14));Donnees_2014!$C$4:$C$368;0));"")

... de cette manière, pas de message d'erreur si pas de date en A14, ni dans les cas (fin février 2016, par exemple) où certaines dates ne seraient pas communes aux deux feuilles

Ça te va comme explication?

 

[UnknownUser]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Et bien merci beaucoup... c'est un peu plus clair dans mon esprit.

Je suis à chaque fois bluffé des capacités d'excel!

Par contre, la nouvelle formule marche également mais excel met un petit triangle vert et quand je clique sur le panneau "attention", il me met "formule incohérente" (mais elle a l'air de marcher).

 

[Modeste]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Re³,

excel met un petit triangle vert

L'aide d'Excel t'aurait renseigné bien plus vite et plus complètement que moi

J'y ai lu (entre autres)

Formules incohérentes avec d’autres formules de la zone: La formule ne correspond pas à la structure des autres formules situées à proximité. Dans de nombreux cas, les formules qui sont adjacentes à d’autres formules diffèrent uniquement par les références de cellules utilisées.

Le lecteur attentif en déduira donc qu'Excel ne signale pas que la formule est erronée, mais simplement qu'elle est différente de celles qui sont au-dessus, en-dessous, à droite et/ou à gauche.
Vois ça comme le correcteur orthographique de Word: si un terme n'est pas reconnu, il sera souligné en rouge ... Ça ne veut pas dire qu'il n'existe pas (inversement, hélas, ce n'est pas parce qu'aucune erreur n'est signalée qu'il n'y en a aucune!

 

[UnknownUser]

Re : Aide: intégration d'une vérification de similitude de caractères dans une formul

Et bien écoute merci pour tout!