Affichaged'une somme "aujourdh'ui "du mois en cours

[PGPC]

Bonsoir ,ou plutot bonjour ...

je viens resolliciter votre aide pour un truc qui je pense ne doit pas être didfficile mais qui éechappe au peu de logique dont je suis pourvu

j'ai un classeur de 12 mois
les mois fonctionnent avec liaison , je voudrai que s'affiche sur ma feuille index, case (total ) la somme du dernier mois en cours et non le cumul des sommes de chaque mois ...
J'ai essayé avec la fonction aujourdh'ui mais en vain et c'est précisement la somme du jour que je veux connaitre

Merci pour votre aide et bonne journée

Cordialement

pgpc

 

[andré]

Salut PGPC,

Sous le post :

<http://www.excel-downloads.com/html/French/forum/read.php?f=1&i=94087&t=93929>

tu trouveras la solution proposée par Monique.

Bon dimanche.
Ândré.

 

[PGPC]

Bonjour le Forum,Bonjour André ,



J'ai regardé le lien "Monique" pour affichage mais très honnêtemùent je n'y comprend rien..CA VIENDRA!....(.LOL)

Si quelqu'un avait un exemple de la fonctionde Monique plus facile ce serait sympa ....

je reformule

j'ai un classeur avec 13 onglets " 12 mois" et "1 page d'acceuil"

page d'acceuil _ janvier_ fevrier .................juin ..etc...

sur chaque feuille j'ai un total mensuel

je voudrai que ce soit le total par exemple d' aujourd'hui la somme du 13 juin qui s'affiche dans une cellule "total" de ma page d'acceuil ..


"les autres mois ne sont plus à totaliser"


le mos prochain , nous serons en juillet et je voudrai que ce soit la somme du jour x du mois de juillet qui s'affiche ,

Voilà mon épineux problème qui n'est pas si facile à résoudre ...

Merci pour votre aide

Bonne fin de soirée

PGPC

 

[Monique]

Bonjour,

=INDIRECT(TEXTE(AUJOURDHUI();"mmmm")&"!K17")
Mais il faut que tes onglets aient la même orthographe que Excel
Tu mets un accent sur le 1er e de février, tu enlèves l'espace après les 4 lettres de mars, etc.

C'est comme si tu écrivais :
=juin!K17
ou bien (mais ça ne servirait à rien !)
=INDIRECT("juin!"&"K17") ou bien =INDIRECT("juin" & "!" & "K17")
En fait, on "concatène" le nom de la cellule.

Si tu veux le contenu de la cellule K17 du mois précédant le mois en cours :
=INDIRECT(TEXTE(DATE(;MOIS(AUJOURDHUI())-1;1);"mmmm")&"!K17")

Par contre, tu parles d'afficher le contenu de la cellule du jour ?
Il n'y a pas de dates dans tes feuilles.
On admet que le nombre du 1er de chaque mois est en B1, du 2 en B2, etc
Pour avoir la somme d'aujourd'hui :
=INDIRECT(TEXTE(AUJOURDHUI();"mmmm")&"!B"&TEXTE(AUJOURDHUI();"j"))
Equivaut à
=juin!B13 en ayant concaténé le mois, le B de la colonne et le jour.

 

[Monique]

Re,

On peut faire plus court pour la dernière, le contenu de la cellule B13 de la feuille de juin :
=INDIRECT(TEXTE(AUJOURDHUI();"mmmm")&"!B"&JOUR(AUJOURDHUI()))

 

[PGPC]

Bonsoir le forum, Bonsoir Monique ,


J'ai essayé de suivre la marche a suivre mais rien à faire ,c'est, je le déplore au dessus de mes capacités...

je rejoins un petit ZIP qui cette fois sera plus explicite ...

Monique , j'espère que je ne t'ai pas fait bosser pour rien??
Non, je suis sur tout le monde ne doit pas connaitre la fonction indirect et sa mise en application ou alors je suis une vraie quiche (lol)

Donc si vous voulez tester la fonction indirect que Monique indique n'hésitez pas , servez vous de mon fichier d'exemple et lorsque vous serez en maitrise totale de la fonction , renvoyez la moi incorporée à l'exemple(lol)

Merci et bonne journée à tous

PGPC

et Bravo l'équipe de France

 

[Monique]

Bonjour,

Hier, tes feuilles avaient le nom des mois, aujourd'hui, elles ont un nom à rallonge.
Dans le post d'hier :
"Mais il faut que tes onglets aient la même orthographe que Excel
Tu mets un accent sur le 1er e de février, tu enlèves l'espace après les 4 lettres de mars, etc."

En février, il n'y a pas d'accent
En mai, il y a un espace après le nom de l'onglet
En juillet, idem
En août, tu cumules, il n'y a pas d'accent et il y a un espace

Aujourd'hui, la formule doit renvoyer la somme de plusieurs cellules, hier, elle devait renvoyer le contenu d'une cellule.

Bref, j'ai adapté la formule au nouveau nom des feuilles et à ta nouvelle demande.
En G13 de la feuille "accueil" :
=SOMME(INDIRECT(TEXTE(AUJOURDHUI();"mmmm")&"_inventaire!E11"):INDIRECT(TEXTE(AUJOURDHUI();"mmmm")&"_inventaire!E17"))
pour le mois précédent (si tu veux, seulement) :
=SOMME(INDIRECT(TEXTE(DATE(;MOIS(AUJOURDHUI())-1;1);"mmmm")&"_inventaire!E11"):INDIRECT(TEXTE(DATE(;MOIS(AUJOURDHUI())-1;1);"mmmm")&"_inventaire!E17"))
Ces formules sont dans le fichier joint.
Dans le fichier, tu as d'autres formules, de couleur bleue.
Elles ne servent pas dans le fichier, mais elles peuvent peut-être t'aider à mieux comprendre.

 

[PGPC]

Monique, 1000 merci !!!!!

Qu'elle démonstration!...

si je pouvais t'envoyer des fleurs, je le ferai.....


Bonne journée,

Cordialement
PCPG