Additioner les 10 plus grandes valeurs

[Vilain]

Bonjour à tous,

J'ai une base de données comportant mes différentes informations.
A partir de cette base de données, je définis une matrice grâce au gestionnaire de noms.
Ma matrice est la suivante :
=SI((BaseBSN!$P$2:$P$3000=1)*(BaseBSN!$T$2:$T$3000<TABPARAMETRE!$C$3+2)*(BaseBSN!$AI$2:$AI$3000="CDI")*(BaseBSN!$AL$2:$AL$3000>0);BaseBSN!$AL$2:$AL$3000)
(Je sais grâce à mon cher Job75 que cette matrice fonctionne parfaitement).
Je souhaite faire la somme de mes 10 plus gros salaires (qui correspondent à ma colonne AL dans ma matrice) grâce à cette formule validé en matricielle :
=SOMMEPROD((Matrice10percN)*($AL$2;$AL$100>=GRANDE.VALEUR(SI(Matrice10percN;$AL$2;$AL$100);10))*$AL$2;$AL$100)
La formule me ramène un #N/A, je ne comprends pas pourquoi.
Je joins mon fichier pour plus de compréhension.

Je fais appel à vos âmes charitables.

Merci d'avance.

Gillus

 

[job75]

Re : Additioner les 10 plus grandes valeurs

Rebonjour Gillus,

Sur le fil déjà traité aujourd'hui tu avais tout ce qu'il fallait pour trouver cette formule :

=SOMMEPROD(GRANDE.VALEUR(MatriceN;LIGNE(1:10)))

Encore faut-il que la définition de MatriceN soit correcte... Il y a encore un astérisque à la place du point-virgule !

A+

 

[Habitude]

Re : Additioner les 10 plus grandes valeurs

Bonjour

too late...

 

[Vilain]

Re : Additioner les 10 plus grandes valeurs

Bonjour,

Je reviens sur ce sujet avec une nouvelle demande.
J'ai mis à jour mon fichier exemple avec les éléments nécessaires et en corrigeant la faute remarquée par Job75.
Je souhaite compter le nombre de femmes présentes dans les 10 plus hautes rémunérations en fonction des critères préalablement cités et en ajoutant la notion de site (le site se choisit sur l'onglet tabparametre en cellule B2).

Merci d'avance.

Gilles

 

[job75]

Re : Additioner les 10 plus grandes valeurs

Bonjour Gillus,

Vois le fichier joint avec cette formule en F2 :

=SOMMEPROD((MatriceN>=GRANDE.VALEUR(MatriceN;10))*(BaseBSN!AB$2:AB$100="F"))

Elle ne pose pas de problème car tous les salaires sont différents.

Note bien que la formule du nom MatriceN n'utilise plus la fonction SI :

=(BaseBSN!$P$2:$P$100=1)*(BaseBSN!$T$2:$T$100<=TABPARAMETRE!$C2)*(BaseBSN!$AA$2:$AA$100=TABPARAMETRE!$B$2)*(BaseBSN!$AI$2:$AI$100="CDI")*(BaseBSN!$AL$2:$AL$100>0)*(BaseBSN!$AL$2:$AL$100)

En effet il ne faut plus de "FAUX" dans la matrice car "FAUX" est supérieur à tout nombre.

Edit : note encore que si l'on efface le site en B2 MatriceN ne contient que des zéros.

En F2 on obtient donc le nombre total de femmes (41).

A+

 

[job75]

Re : Additioner les 10 plus grandes valeurs

Re,

On peut préférer utiliser la formule avec SI pour définir MatriceN.

Dans ce cas modifier la formule en F2 :

=SOMMEPROD(ESTNUM(MatriceN)*(MatriceN>=GRANDE.VALEUR(MatriceN;10))*(BaseBSN!AB$2:AB$100="F"))

Fichier (2).

A+

 

[job75]

Re : Additioner les 10 plus grandes valeurs

Bonjour Gilles, le forum,

Un fichier plus soigné avec cette formule en F2 :

=SI(NB(MatriceN)<10;"";SOMMEPROD(ESTNUM(MatriceN)*(MatriceN>=GRANDE.VALEUR(MatriceN;10))*(BaseBSN!$AB$2:$AB$100=F$1)))

Si plusieurs personnes avaient le 10ème salaire, le total Femmes-Hommes dépasserait 10.

Edit : j'ai aussi ajouté "Tous" dans la liste de validation en B2, MatriceN est modifié en conséquence.

A+

 

[Vilain]

Re : Additioner les 10 plus grandes valeurs

Bonjour,

Encore merci pour toutes ces réponses. Je regarde avec attention tout ça.

A plus