1er espace depuis la droite

[eastwick]

Bonjour à toutes et tous,

J'aimerais connaître une formule pour déterminer l'emplacement du premier espace d'un groupe de mot mais en commençant par la droite. Ex : Jean-Marie LAPRUNE ----> la formule donnera le résultat 8.
Je vous remercie.

 

[R@chid]

Re : 1er espace depuis la droite

Bonjour,
ta chaine en A1, la formule en B1 :

=EQUIV(" ";STXT(A1;NBCAR(A1)+1-LIGNE(INDIRECT("1:"&NBCAR(A1)));1);0)

@ valider par Ctrl+Shift+Enter


@ + +

 

[R@chid]

Re : 1er espace depuis la droite

Re,
une formule classique :

=NBCAR(STXT(A1;TROUVE("|";SUBSTITUE(A1;" ";"|";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";))));5^5))

@ + +

 

[eastwick]

Re : 1er espace depuis la droite

Impec ! merci beaucoup !

 

[CISCO]

Re : 1er espace depuis la droite

Bonjour à tous, bonjour R@chid

Une variante parmi d'autres, si tu as plusieurs espaces vides dans ta colonne

NBCAR(A1)-CHERCHE("µ";SUBSTITUE(A1;" ";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";""))))

et si tu n'en as qu'un systématiquement

NBCAR(A1)-CHERCHE(" ";A1)

@ plus

 

[job75]

Re : 1er espace depuis la droite

Bonjour à tous,

@ CISCO : il me semble que tu as oublié un +1 non ?

=NBCAR(A1)+1-TROUVE("µ";SUBSTITUE(A1;" ";"µ";NBCAR(A1)-NBCAR(SUBSTITUE(A1;" ";))))

A+

 

[BOISGONTIER]

Re : 1er espace depuis la droite

bonjour

=EQUIV(" ";STXT(A1;NBCAR(A1)-LIGNE($1:$255);1);0)

Valider avec maj+ctrl+entrée

jb

 

[CISCO]

Re : 1er espace depuis la droite

Bonsoir à tous

Bonjour à tous,

@ CISCO : il me semble que tu as oublié un +1 non ?

A+

Et oui