zone d'impression variable en fonction des cellule

[Ilino]

Bonjour forum
Je cherche un code VBA pour définir zone d’impression (variable) par un USF
EXEMPLE
Clic sur un bouton => usf : zone d’impression de la cellule B3 au L25 et cette zone sera applicable pour le reste des pages
grazie

 

[job75]

Re : zone d'impression variable en fonction des cellule

Bonjour Ilino,

Si l'on entre la référence "B3:L25" dans TextBox1 :

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error Resume Next
For Each w In Worksheets
  w.PageSetup.PrintArea = TextBox1
Next
If Err Then MsgBox "Référence non valide !"
End Sub

A+

 

[Ilino]

Re : zone d'impression variable en fonction des cellule

Re maitre
ci joint mon fichier , je souhaiterai faire deux texbox au lieu tow
c a d mettre de B3 dans Textbox 1 et L25 dans Textbox2
grazie encore

 

[job75]

Re : zone d'impression variable en fonction des cellule

Re,

Elémentaire, je n'ouvre même pas ton fichier !

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error Resume Next
For Each w In Worksheets
  w.PageSetup.PrintArea = TextBox1 & ":" & TextBox2
Next
If Err Then MsgBox "Référence non valide !"
End Sub

A+

 

[job75]

Re : zone d'impression variable en fonction des cellule

Re,

Si l'on veut annuler les zones d'impression, laisser les 2 TextBoxes vides :

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error Resume Next
For Each w In Worksheets
  w.PageSetup.PrintArea = IIf(TextBox1 & TextBox2 = "", "", TextBox1 & ":" & TextBox2)
Next
If Err Then MsgBox "Référence non valide !"
End Sub

A+

 

[Ilino]

Re : zone d'impression variable en fonction des cellule

Bonjour maitre
grazie c'est nockel

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error Resume Next
For Each w In Worksheets
  w.PageSetup.PrintArea = IIf(TextBox1 & TextBox2 = "", "", TextBox1 & ":" & TextBox2)
Next
Worksheets("FGP 2014").PrintOut
If Err Then MsgBox "Référence non valide !"
Exit Sub
End Sub

je veux ajouter dans ce code une fois j'ai lancé l'impression mon USF ce masque??

EDIT : si l'imprission est treminée fermer USF
A+

 

[Ilino]

Re : zone d'impression variable en fonction des cellule

Bjr forum
puis je avoir votre help
a+

 

[job75]

Re : zone d'impression variable en fonction des cellule

Bonsoir Ilino,

Avec ce que je t'ai donné tu devais être capable de compléter le code :

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error Resume Next
For Each w In Worksheets
  w.PageSetup.PrintArea = IIf(TextBox1 & TextBox2 = "", "", TextBox1 & ":" & TextBox2)
Next
If Err Then
  MsgBox "Référence non valide !"
Else
 Unload Me
 Sheets("FGP 2014").PrintOut
End If
End Sub

A+

 

[job75]

Re : zone d'impression variable en fonction des cellule

Bonjour Ilino, le forum,

Un code plus complet qui sélectionne la TextBox erronée :

Private Sub CommandButton1_Click()
Dim w As Worksheet
On Error GoTo 1
For Each w In Worksheets
  w.PageSetup.PrintArea = IIf(TextBox1 & TextBox2 = "", "", TextBox1 & ":" & TextBox2)
Next
On Error GoTo 0
Unload Me
Sheets("FGP 2014").PrintOut
Exit Sub
1 MsgBox "Référence non valide !", 48
If TypeName(Evaluate("'" & w.Name & "'!" & TextBox1 & ":A1")) <> "Range" Then
  TextBox1.SetFocus: TextBox1.SelStart = 0: TextBox1.SelLength = Len(TextBox1)
Else
  TextBox2.SetFocus: TextBox2.SelStart = 0: TextBox2.SelLength = Len(TextBox2)
End If
End Sub

A+

 

[Ilino]

Re : zone d'impression variable en fonction des cellule

Bonjour Forum, Bonjour MAITRE
GRAZIE GRAZIE C'est nickel
A+