VBA supprimer lignes cellules commençant par

[rocky9]

Bonjour,

J'aimerais supprimer les lignes dont la colonne B contient un code commençant par Z

J'ai essayé ce code sur ce fichier mais sans succès

de = Sheets("En Dessous Du Seuil").Cells(Application.Rows.Count, 2).End(xlUp).Row
    For x = de To 2 Step -1
            If Left$(Cells(x, 2).Value, 1) = "Z" Then Rows(x).Delete = True
    Next x

Cordialement

 

[Pierrot93]

Re : VBA supprimer lignes cellules commençant par

Bonjour,

pas ouvert ton fichier, mais essaye peut être ainsi :

If Cells(x, 2).Value Like "Z*" Then Rows(x).Delete = True

bonne journée
@+

 

[Guest]

Re : VBA supprimer lignes cellules commençant par

Bonjour,

Hello Pierrot🙂

Sub SupprimerLignesZ()
    Dim plageDatas As Range, plageToDelete As Range
    Dim Ligne As Long
    With Sheets("En Dessous Du Seuil")
        For Ligne = .Cells(.Rows.Count, 2).End(xlUp).Row To 2 Step -1
            'Pour aller plus vite,créer une union des cellules
            'dont les lignes sont à supprimer
            If .Cells(Ligne, 2) Like "Z*" Then
                'Si l'union de la plage n'existe pas encore
                'on créer une première référence à la cellule
                If plageToDelete Is Nothing Then
                    Set plageToDelete = .Cells(Ligne, 2)
                Else
                    'sinon on ajoute à l'union des cellules
                    Set plageToDelete = Union(plageToDelete, .Cells(Ligne, 2))
                End If
                    
            End If
        Next
    End With
    'si notre boucle a trouver quelque chose à supprimer
    'on supprime les lignes comptlètes correspondant à l'union
    If Not plageToDelete Is Nothing Then plageToDelete.EntireRow.Delete
End Sub

A+

 

[rocky9]

Re : VBA supprimer lignes cellules commençant par

Bonjour messieurs,

Merci pour vos codes, ils fonctionnent mais lorsque dans ma colonne B je n'ai pas un code service mais un message d'erreur, la macro plante sur le

If .Cells(Ligne, 2) Like "Z*"

 

[Guest]

Re : VBA supprimer lignes cellules commençant par

re,

  If Not IsEmpty(.Cells(Ligne, 2)) Then
        If .Cells(Ligne, 2).Text Like "Z*" Then
            '.....Suite code
        End If
    End If

A+

 

[Pierrot93]

Re : VBA supprimer lignes cellules commençant par

Re, bonjour Hasco🙂

une autre approche :

If Not IsError(ActiveCell) Then If ActiveCell Like "L*" Then MsgBox "ok"