VBA, fermer userform avec bouton valider

[boxi]

Bonjour,

Je travaille sur un document excel avec macro vba,
J'ai réalisé un userform avec une combobox et un bouton "valider".
J'aimerai que ce bouton valider lance la macro et ferme l'userform automatiquement, ce qui permettrait d'éviter de passer par un bouton "quitter" ou la croix rouge en haut à droite.
Le document devant utilisé par des personnes peut habituées à excel il doit être très simple à manier.
Je vous remercie de votre aide car je sèche sur la partie "fermeture" de la macro
Boxi

 

[Papou-net]

Re : VBA, fermer userform avec bouton valider

Bonsoir boxi,

Si j'ai bien compris (car la feuille liste commune ne figure pas dans ton fichier), il suffit de remplacer Exit Sub par Unload Me.

Ex :

Private Sub CommandButton1_Click()
 Dim commune As String
 Dim departement As String
    commune = ComboBox1.Value
    Sheets("liste commune").Activate
    Range("a8").Activate
   Do While ActiveCell.Value <> ""
        If commune = ActiveCell.Value Then
            Range("a2") = ActiveCell.Value
            Range("b2") = ActiveCell.Offset(0, 1).Value
            Range("c2") = ActiveCell.Offset(0, 2).Value
            Range("d2") = ActiveCell.Offset(0, 3).Value
            Range("e2") = ActiveCell.Offset(0, 4).Value
            Range("f2") = ActiveCell.Offset(0, 5).Value
            Unload Me '  <--- à la place de Exit Sub
        End If
        ActiveCell.Offset(1, 0).Activate
    Loop
   Sheets("liste commune").Activate
   Range("a1").Activate
End Sub

Si tu désires conserver les données dans le formulaire combo, il faut alors remplacer par Me.Hide

Cordialement.

 

[Robert]

Re : VBA, fermer userform avec bouton valider

Bonsoir Boxi, Papou-net, bonsoir le forum,

En pièce jointe ton fichier modifié avec le code ci-dessous :

Private Sub CommandButton1_Click() 'bouton "Valider"
Dim c As String 'déclare la variable c (Commune)
Dim r As Range 'déclare la varaible r (Recherche)
c = ComboBox1.Value 'définit la variabe c
With Sheets("liste commune") 'prend en compte l'onglet "liste commune"
    Set r = .Range("dernier").Find(c, , xlValues, xlWhole) 'définit la recherche r (recherche la commune dans la plage nommée "dernier")
    If Not r Is Nothing Then 'condition : si il existe au moins une occurrence trouvée
        .Range("A2") = r.Value 'place c en A2
        .Range("B2") = r.Offset(0, 1).Value 'place le nom de la commune en B2
        .Range("C2") = r.Offset(0, 2).Value 'place le total en C2
        .Range("D2") = r.Offset(0, 3).Value 'place le total avec en D2
        .Range("E2") = r.Offset(0, 4).Value 'place le total sans en E2
        .Range("F2") = r.Offset(0, 5).Value 'place les personnes couverte en F2
    Else 'sinon
        .Range("A2:F2").ClearContents 'efface la plage A2:F2
    End If 'fin de la condition
End With 'fin de la prise en compte de l'onglet "liste commune"
Unload Me 'vide et ferme l'USerForm
End Sub

Le fichier :

 

[boxi]

Re : VBA, fermer userform avec bouton valider

merci infiniment pour les réponses, ça marche et c'est super