XL 2019 VBA et Power Query - Barre de progression

Option Explicit
Public TempsPlannif
Public PremiereFois As Boolean
Sub LancerTempsRestantPlanifStatusBar()
Dim i As Long, ifin As Long

    PremiereFois = True
    TempsRestantPlanifStatusBar
    ' Boucle bidon juste pour simuler le traitement (sans boucle)
    ifin = 20000
    For i = 1 To ifin
        Range("b1") = i
        Range("b2") = ifin - i
        DoEvents ' pour afficher
    Next i
    MsgBox "boucle fini"
    On Error Resume Next
    Application.OnTime TempsPlannif, Procedure:="TempsRestantPlanifStatusBar", Schedule:=False
    Application.DisplayStatusBar = False
End Sub
Sub TempsRestantPlanifStatusBar()
Dim NomTraitement As String
Dim Tps As Double
Dim TpsRest As Date, Duree As Long
Dim TpsRestAffiche As String
Static T0 As Double
    'Texte dans la StatusBar

    Duree = 20 'en secondes (doit correspondre en gros à la durée du traitement estimé)

    Application.DisplayStatusBar = True

    If PremiereFois Then
        T0 = Timer
    End If
   'temps restant
    Tps = T0 + Duree - Timer
    If Tps > 0 Then
        'traitement non fini
        NomTraitement = " Traitement en cours, veuillez patienter ...  "
        TpsRest = TimeSerial(0, 0, Tps)
        TpsRestAffiche = "(Temps restant : " & Format(TpsRest, "hh\hmm\m\nss\s") & ")"
    Else
        'traitement terminé (normalement)
        NomTraitement = " Le Traitement devrait être terminé ...  "
        TpsRest = TimeSerial(0, 0, -Tps)
        TpsRestAffiche = "(Temps dépassé depuis : " & Format(TpsRest, "hh\hmm\m\nss\s") & ")"
    End If
    
    Application.StatusBar = NomTraitement & TpsRestAffiche
    PremiereFois = False

    ' ici on raffraichit l'affichage de la SttusBar toutes les 5 secondes
    TempsPlannif = Now + TimeValue("00:00:05")
    Application.OnTime TempsPlannif, "TempsRestantPlanifStatusBar"


End Sub

Sub CompterLignesCSV()
Dim idxfic#, fichier$, nbrLignes&, x$
   fichier = "C:\toto\1 000 000 lignes.csv"
   On Error GoTo Err001
   idxfic = FreeFile()
   Open fichier For Input As #idxfic
   Do While Not EOF(idxfic): nbrLignes = nbrLignes + 1: Line Input #idxfic, x: Loop
Err001:
   Close #idxfic
   MsgBox Format(nbrLignes, "#,##0 lignes\.")
End Sub