XL 2010 VBA : clic droit sur SelectionChange

[F22Raptor]

Hello,
J'utilise dans ma feuille une procédure Selection_Change qui effectue une action sur la cellule cliquée fait partie d'une zone
Private Sub Work
If Not Application.Intersect(Target, Range("A1:A100") Is Nothing Then

Y a-t-il un moyen de ne pas effectuer les actions si le clic s'est fait avec le bouton droit ?

Merci !

 

[Lone-wolf]

Bonjour F22Raptor, le Forum 🙂

Dans ce cas, tu peux utiliser directement
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
Et pas besoin d'ajouter Application, If Not Intersect suffit.

 

[F22Raptor]

Merci LoneWolf : je vais regarder ça

 

[Lone-wolf]

Re

@F22Raptor : un exemple

Private Sub Worksheet_BeforeRightClick(ByVal R As Range, Cancel As Boolean)
If Not Intersect(R, Range("A2:A100")) Is Nothing Then
Cancel = True
R.Offset(0, 2) = "x"
End If
End Sub

 

[F22Raptor]

Je n'arrive pas à combiner les deux : je joins un fichier exemple

 

[job75]

Bonjour F22Raptor, Lone-wolf,

Quand on sélectionne une cellule par clic droit la macro SelectionChange s'exécute avant la macro BeforeRightClick.

Il faut donc reporter la 1ère action pour pouvoir tester la 2ème :

Dim arret As Boolean 'mémorise la variable

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
arret = False
If Target.Count > 1 Or Intersect(Target, Range("C4:C16")) Is Nothing Then Exit Sub
Application.OnTime 1, Me.CodeName & ".Action" 'reporte l'exécution
End Sub

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
arret = True
If Intersect(Target, Range("C4:C16")) Is Nothing Then Exit Sub
Cancel = True
'---suite---
End Sub

Private Sub Action()
If arret Then arret = False: Exit Sub
ActiveCell.Offset(, 1) = "X"
End Sub

Fichier joint.

A+

 

[F22Raptor]

Subtil ! Merci Job !

 

[Lone-wolf]

Bonjour Gerard 🙂

@job75

Merci pour ton intervention, je ne savais pas comment boutiquer ça.

 

[Dranreb]

Bonjour.
Il y a ça qui a l'air de marcher :

Option Explicit
Private Cible As Range
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
   Set Cible = Target
   Application.OnTime Now, Me.CodeName & ".Clic"
   End Sub
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
   Set Cible = Nothing
   Cancel = True
   End Sub
Public Sub Clic()
   If Cible Is Nothing Then Exit Sub
   If Not Application.Intersect(Cible, Range("C4:C16")) Is Nothing Then
      Cible.Offset(0, 1) = "X"
      End If
   Set Cible = Nothing
   End Sub

 

[F22Raptor]

joli et propre !
Merci Dran

 

[Dranreb]

Remarque: Je n'ai pas vu que Job75 , que je salue, avait proposé pratiquement la même solution bien avant moi.