XL 2019 Valeurs unique suivant une condition

[Xxaann]

Bonjour,

J'utilise cette formule pour avoir le nombre de valeurs uniques dans une colonne:
=SOMMEPROD(('MO-99'!E:E<>"")/NB.SI('MO-99'!E:E;'MO-99'!E:E&""))

Par contre je voudrais y ajouter une condition, si dan sla colonne 'MO-99'!F:F la valeur est égale à H4.

J'y arrive pas du tout...

Merci pour votre aide
Nico

 

[JHA]

Bonjour à tous,

Tu auras peut-être une réponse en joignant un fichier exemple.

JHA

 

[Xxaann]

ok voici fichier joind.

petite coquille, ce n'est pas le nombre de valeurs unique mais le nombre de valeurs différentes... sorry.

dans l'exemple, en H7 je voudrait avoir le nombre de valeurs différentes suivant la date en G7

 

[sylvanu]

Bonjour Xxaann, JHA,
Peut être avec :

=SOMMEPROD(1/(NB.SI(C2:C27;C2:C27)+(C2:C27=0)))-NB.VIDE(C2:C27)
=SOMME(SI(D2:D27=G7;1/NB.SI.ENS(C2:C27;C2:C27;D2:D27;D2:D27)))

Seconde formule matricielle donc à valider par Maj+Ctrl+Entrée sur anciennes versions XL.

 

[job75]

Bonjour Xxaann, JHA, sylvanu,

Avec un tableau structuré c'est quand même mieux.

Formule matricielle en H7, à valider par Ctrl+Maj+Entrée :

=SOMME(N(SIERREUR(EQUIV(Tableau1[Produits]&G7;Tableau1[Produits]&Tableau1[Dates];0)=LIGNE(Tableau1)-1;0)))

A+

 

[JHA]

Bonjour à tous,

Avec la fonction decaler() et le trie des dates dans le tableau structuré.

=SOMMEPROD(ESTTEXTE(DECALER($C$1;EQUIV($G$7;Tableau1[Dates];0);;NB.SI(Tableau1[Dates];$G$7)))*(1/NB.SI(DECALER($C$1;EQUIV($G$7;Tableau1[Dates];0);;NB.SI(Tableau1[Dates];$G$7));DECALER($C$1;EQUIV($G$7;Tableau1[Dates];0);;NB.SI(Tableau1[Dates];$G$7)))))

JHA

 

[sylvanu]

Bonjour Job, JHA,
Mais sans TDS cette formule est plus courte :

=SOMME(SI(D2:D27=G7;1/NB.SI.ENS(C2:C27;C2:C27;D2:D27;D2:D27)))

 

[Xxaann]

Merci à tous!
J'ai opté pour la solution de Sylvanu, beaucoup plus courte.
Bonne journée,
à tous