Utiliser la fonction si avec des formats horaires

[TIF]

Bonjour,

Je voudrais utiliser une formule si sur une cellule en format horaire hh:mm

SI cellule E5 > à 9:30
VRAI = E5-D5-S5
FAUX = E5-D5

L'ensemble de mes cellules sont bien en format horaire hh:mm.

Ci joint fichier

Merci à toutes les bonnes âmes qui voudront bien me répondre.

TIF

 

[Modeste geedee]

Re : Utiliser la fonction si avec des formats horaires

Bonsour®

Bonjour,

Je voudrais utiliser une formule si sur une cellule en format horaire hh:mm

SI cellule E5 > à 9:30
VRAI = E5-D5-S5
FAUX = E5-D5

L'ensemble de mes cellules sont bien en format horaire hh:mm.
TIF

=SI(E30>"9:30";E30-D30-S30;E30-D30)

 

[TIF]

Re : Utiliser la fonction si avec des formats horaires

Merci beaucoup pour votre réponse.

La formule est bien acceptée par Excell.
Cependant quand on essaie c'est à s'arracher les cheveux :

La formule rentrée est
si E5>"9:31"
VRAI E5-D5
FAUX E5-D5-S5

Si E5=12:00
D5=6:00
S5=0:20
Le calcul ressort à 5:40 soit le calcul de la réponse FAUX alors que E5 est bien supérieure à 9:31

J'en perds mon latin....

Si vous avez une explication....

Cordialement

TIF

 

[job75]

Re : Utiliser la fonction si avec des formats horaires

Bonjour,

Il faut transformer le texte "9:30" en heure numérique :

=SI(E5>1*"9:30";E5-D5-S5;E5-D5)

ou aussi :

=SI(E5>TEMPSVAL("9:30");E5-D5-S5;E5-D5)

A+

 

[Modeste geedee]

Re : Utiliser la fonction si avec des formats horaires

La formule rentrée est
si E5>"9:31"
VRAI E5-D5
FAUX E5-D5-S5

Si E5=12:00
D5=6:00
S5=0:20
Le calcul ressort à 5:40 soit le calcul de la réponse FAUX alors que E5 est bien supérieure à 9:31

pour l'évaluation de :=SI(E5>9:31;E5-D5;E5-D5-S5)

• il faut transformer les temps en chaine de caractère
• pour comparer il faut convertir cette meme chaine en n° de série

cette dernière s'effectue automatiquement par l'utilisation d'un opérateur algébrique neutre :

• 1*"9:31"
• ou 0+"9:31"
• ou "9:31"/1
• ou N("9:31")
• ou --"9:31"

=SI(E5>1*"9:31";E5-D5;E5-D5-S5)

ou bien (sourire ... 3 caractères en moins)

=E5-D5-SI(E5>1*"9:31";0;S5)

 

[JCGL]

Re : Utiliser la fonction si avec des formats horaires

Bonjour à tous,
Salut Gérard,

Tu peux aussi essayer :

=MOD(E5-D5;1)-SI(E5>"09:30";S5;0)

A + à tous

 

[job75]

Re : Utiliser la fonction si avec des formats horaires

Re, salut Jean-Claude 🙂

La fonction SI est très gourmande en octets-mémoire, voyez ce fil :

https://www.excel-downloads.com/threads/nombre-doctets-memoire-dune-expression.129833/

Ici la solution la plus légère est sans nul doute :

=E5-D5-S5*(E5>--"9:30")

Edit pour Modestegeedee : N("9:31") renvoie 0...

A+

 

[TIF]

Re : Utiliser la fonction si avec des formats horaires

Merci à tous pour vos réponses. L'ensemble de vos réponses fonctionnent. Vous êtes des as !!
Ciao a tutti
Tif