Userform listbox

[nherambo]

Bonjour à tous,

J'ai un problème sur le fichier ci joint. Je pense que la structure de mon code VBA n'est pas bonne.

Concrètement, mon objectif est qu'en entrant ma donnée dans "number", il me renvoie plusieurs données correspondantes dans la listbox : number, correspondance, equivalence, montant.
Or il me renvoie toutes les valeurs.

Je suis ouvert à toutes vos remarques et si vous avez des questions je pourrais repréciser mes propos.

Merci pour votre aide.

Nherambo

 

[Denis]

Re : Userform listbox

Bonjour nherambo et le forum,
N'oublie pas de vider ta listbox avant d'y remettre de nouvelles données.
Bon courage et à+
Denis

 

[nherambo]

Re : Userform listbox

Bonjour,

Pour ça, pas de problème. Par contre si tu regardes mon fichier de plus près, tu verras que la valeur de la colonne 4 ne correspond pas à la bonne valeur. Et je ne sais pas comment corriger ça

 

[Papou-net]

Re : Userform listbox

Bonjour nherambo, Denis, le Forum,

Voici comment moi je verrais la chose:

Premièrement, je remplacerais la procédure Number_AfterUpdate par l'événement number_Change.

Ensuite, je modifierais le code comme suit:

Private Sub Number_AfterUpdate()

End Sub

Private Sub number_Change()
Maligne = Sheets("Sheet1").Range("A3000").End(xlUp).Row + 1
Sheets("Sheet1").Range("A" & Maligne) = Me.number


Dim F1 As Worksheet
Set F1 = Sheets("Sheet2")
Dim F2 As Worksheet
Set F2 = Sheets("Sheet3")
Dim Cel As Range
With Me.ListBox1
    .Clear
    .ColumnCount = 4
    .ColumnWidths = "40;40;40"
    For Each Cel In F1.Range("B:B").SpecialCells(xlCellTypeConstants)
      If Cel.Text = number.Value Then
        .AddItem Cel.Value
        .List(.ListCount - 1, 1) = Cel.Offset(0, 1).Value
        .List(.ListCount - 1, 2) = Cel.Offset(0, 3).Value
        .List(.ListCount - 1, 3) = Cel.Offset(0, 11).Value
      End If
    Next

End With
End Sub

A +

Cordialement.

 

[nherambo]

Re : Userform listbox

Bonjour Papou-net, Denis, le Forum,

Merci pour vos réponses. Mon problème maintenant est que je n'arrive pas à afficher la colonne amount qui se trouve sur le feuille 3 en colonne M. Et c'est là ma principale difficulté étant donné qu'il faut faire référence à une autre feuille.

Merci pour vos suggestions

Nherambo

 

[Papou-net]

Re : Userform listbox

RE:

OK, alors essaie comme ceci, ça devrait fonctionner:

Private Sub number_Change()
Maligne = Sheets("Sheet1").Range("A3000").End(xlUp).Row + 1
Sheets("Sheet1").Range("A" & Maligne) = Me.number

Dim F1 As Worksheet
Set F1 = Sheets("Sheet2")
Dim F2 As Worksheet
Set F2 = Sheets("Sheet3")
Dim Cel As Range, Comb As Range

With Me.ListBox1
    .Clear
    .ColumnCount = 4
    .ColumnWidths = "40;40;40"
    For Each Cel In F1.Range("B:B").SpecialCells(xlCellTypeConstants)
      If Cel.Text = number.Value Then
        .AddItem Cel.Value
        .List(.ListCount - 1, 1) = Cel.Offset(0, 1).Value
        .List(.ListCount - 1, 2) = Cel.Offset(0, 3).Value
        Set Comb = F2.Range("A:A").Find(Cel.Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not Comb Is Nothing Then
          .List(.ListCount - 1, 3) = Comb.Offset(0, 12).Value
        End If
      End If
    Next

End With
End Sub

Cordialement.

 

[nherambo]

Re : Userform listbox

Re Papou-net,

Je viens d'essayer ton code en ajoutant une largeur de colonne pour l'affichage de la 4ème colonne de ma listbox. Mais le montant de la colonne M ne s'affiche pas encore dans la listbox.

A+

 

[Papou-net]

Re : Userform listbox

Re Papou-net,

Je viens d'essayer ton code en ajoutant une largeur de colonne pour l'affichage de la 4ème colonne de ma listbox. Mais le montant de la colonne M ne s'affiche pas encore dans la listbox.

A+

RE:

En es-tu certain, car moi je vois bien l'affichage du montant dans la ListBox ?

Ou bien je n'ai pas compris le problème.

A +

Cordialement.

PS: la copie d'écran jointe correspond à l'utilisation du fichier joint dans ton dernier message.

 

[nherambo]

Re : Userform listbox

Re :
Essaye avec le nombre 4, pour ma part je n'ai pas de montant qui apparaissent.
Là où je bloque, c'est que pour renvoyer le montant, il faut faire référence au numéro de combinaison qui lui-même se réfère au nombre "number" saisi.
Je m'excuse de ne pas avoir clarifié mon problème plus tôt.

A+

 

[Papou-net]

Re : Userform listbox

RE:

Ah ben voilà, c'est plus clair à présent.

Voici comment modifier le code:

Private Sub number_Change()
Maligne = Sheets("Sheet1").Range("A3000").End(xlUp).Row + 1
Sheets("Sheet1").Range("A" & Maligne) = Me.number

Dim F1 As Worksheet
Set F1 = Sheets("Sheet2")
Dim F2 As Worksheet
Set F2 = Sheets("Sheet3")
Dim Cel As Range, Comb As Range

With Me.ListBox1
    .Clear
    .ColumnCount = 4
    .ColumnWidths = "40;40;40"
    For Each Cel In F1.Range("B:B").SpecialCells(xlCellTypeConstants)
      If Cel.Text = number.Value Then
        .AddItem Cel.Value
        .List(.ListCount - 1, 1) = Cel.Offset(0, 1).Value
        .List(.ListCount - 1, 2) = Cel.Offset(0, 3).Value
        Set Comb = F2.Range("A:A").Find(Cel.Offset(0, 2).Value, LookIn:=xlValues, lookat:=xlWhole)
        If Not Comb Is Nothing Then
          .List(.ListCount - 1, 3) = Comb.Offset(0, 12).Value
        End If
      End If
    Next

End With
End Sub

Bon WE.

Cordialement.

 

[nherambo]

Re : Userform listbox

Re Papou-net,

C'est exactement ça. Tout fonctionne parfaitement !
Merci beaucoup.

Bon week-end

Nherambo