Un autre question pour vous

[Trinitybarb]

Sommes-nous limiter lorsqu'on écrit une ligne de conditions ?

Voici un exemple :

J'ai dans mes cellules des mois de janvier à décembre. Je veux que dans ma cellule à côté écrire Q1 pour janvier, février et mars, Q2 pour avril mai et juin, Q3 pour juillet, août et septembre et finalement Q4 pour octobre novembre et décembre.

J'ai écrit cette commande :

=SI(C9="janvier","Q1",(SI(C9="février","Q1",(SI(C9="mars","Q1",(SI(C9="avril","Q2",(SI(C9="mai","Q2",(SI(C9="juin","Q2",(SI(C9="juillet","Q3",(SI(C9="août","Q3",1)))))))))))))))

Lorsque j'essaie d'ajouter septembre il me met un erreur et il ne veut pas continuer.

Est-ce que ma ligne est trop longue ???

merci

 

[tototiti2008]

Re : Un autre question pour vous

Bonjour Trinitybarb,

en effet il me semble que tu es limité à un total de 8 SI imbriqués.
un exemple avec recherchev

 

[PascalXLD]

Re : Un autre question pour vous

Bonjour


Oui tu es limité dans le nombre de si imbriqué

une petite recherche sur le forum te montreras comment passer outre

 

[hoerwind]

Re : Un autre question pour vous

Bonjour,

Les mois en A1:A12
="Q"&ENT((MOIS(1&A1)+2)/3)

 

[Trinitybarb]

Re : Un autre question pour vous

super merci,

des fois je trouve que la solution est souvent la plus simple.

merci encore pour votre aide et de m'avoir éclairé sur la limitation.

bonne journée

 

[Hulk]

Re : Un autre question pour vous

Hello, Tototiti, Pascal, Hoerwind, Trinitybarb

Juste pour préciser qu'avec des virgules , au lieu des points-virgules ; une formule ne peut fonctionner.

Mais de toutes manières, en effet la formule avec autant de Si n'est pas possible... comme le dis Tototiti, limité à huit.

Avec des SI et OU imbriqués, ça fait que 4 SI...Peut-être que

=SI(OU(C9="janvier";C9="février";C9="mars");"Q1";SI(OU(C9="avril";C9="mai";C9="juin");"Q2";SI(OU(C9="juillet";C9="août";C9="septembre");"Q3";SI(OU(C9="octobre";C9="novembre";C9="décembre");"Q4";""))))

Cdt, Hulk.

Edit : Slt JC, et la tienne que trois ! 😀

Vrai que sympa la petite fonction à Hoerwind... bv.

Bon WE à tous !

Re-Edit: Merci pour la précision JC 😉

Re Robert, vrai que le titre pas très explicite 🙄

 

[JCGL]

Re : Un autre question pour vous

Bonjour à tous,

Bien que la proposition d'Hoerwind soit plus que satisfaisante...
Si tu souhaites imbriquer des SI() :

=SI(OU(C9="janvier";C9="février";C9="mars");"Q1";SI(OU(C9="avril";C9="mai";C9="juin");"Q2";SI(OU(C9="jillet";C9="août";C9="septembre");"Q3";"Q4")))

A+ à tous

Edition : Salut Doc Banner ;-). Les virgules dans les formules sont souvent dues à une version US.

 

[Robert]

Re : Un autre question pour vous

Bonjour le fil, bonjour le forum,

Question interessante traitée par des éminents membres du forum, même le modérateur s'y est mis ! Mais pas un pour dire que le titre était lamentable et ne respectait aucunement la charte du forum... C'est déplorable !!!!

 

[Trinitybarb]

Re : Un autre question pour vous

Désolé pour le titre. Je vais faire de mon mieux la prochaine fois.

bye et merci encore pour toutes ces suggestions.

bye

 

[hoerwind]

Re : Un autre question pour vous

Re,

Pour faire un peu plus long que ma proposition précédente (toujours sans SI) :

="Q"&CHOISIR(EQUIV(A1;{"janvier";"février";"mars";"avril";"mai";"juin";"juillet";"août";"septembre";"octobre";"novembre";"décembre"};0);1;1;1;2;2;2;3;3;3;4;4;4)

="Q"&ENT((EQUIV(A1;{"janvier";"février";"mars";"avril";"mai";"juin";"juillet";"août";"septembre";"octobre";"novembre";"décembre"};0)+2)/3)

 

[Robert]

Re : Un autre question pour vous

Bonjour le fil, bonjour le forum,

Mon reproche ne s'adressait pas à toi Trinitybarb, tu es tout nouveau dans ce forum, mais ça me fait plaisir que tu en tiennes compte. Lis Lien supprimé et du comprendras mieux mon point de vue.

 

[Monique]

Re : Un autre question pour vous

Bonjour,

Pour jouer

="Q"&SOMMEPROD(NB.SI(A1;{"Ja*"."F*"."Mar*";"Av*"."Mai"."Juin";"Juil*"."Ao*"."S*";"O*"."N*"."D*"})*LIGNE($A$1:$A$4))

="Q"&SOMMEPROD(NB.SI(A1;({"Ja*"."F*"."Mar*";"Av*"."Mai"."Juin";"Juil*"."Ao*"."S*";"O*"."N*"."D*"}))*LIGNE(INDIRECT("1:4")))

 

[PascalXLD]

Re : Un autre question pour vous

Bonjour le fil, bonjour le forum,

Question interessante traitée par des éminents membres du forum, même le modérateur s'y est mis ! Mais pas un pour dire que le titre était lamentable et ne respectait aucunement la charte du forum... C'est déplorable !!!!

Tu as raison le titre n'est pas adapté mais bon en ce moment je râle pour assez de trucs pour n'avoir rien dit ici

Un choix que j'assume même si je suis d'accord avec toi et que Trinitybarb l'a compris