tri sur plusieurs feuille

[rodge5895]

Bonjour,
quelle formule permettrait, sur le fichier joint à la page 1, de reporter automatiquement le tri de aa sur les 2 pages suivantes nommées janvier et février (cf. colonnes en rouge)?
Actuellement, je suis obligé de choisir manuellement aa sur toutes les feuilles

merci pour votre aide !
rodge

 

[job75]

Re : tri sur plusieurs feuille

Bonsoir rodge5895,

Ce n'est pas un tri mais un filtrage avec le filtre automatique.

Voyez le fichier joint.

1) Entrez en D3 de la 1ère feuille la formule =SOUS.TOTAL(2;A:A)

Elle permet de créer l'évènement Calculate quand on modifie le filtrage.

2) Mettez cette macro dans le code de la 1ère feuille :

Private Sub Worksheet_Calculate()
Dim w As Worksheet, crit$
'---RAZ---
For Each w In Worksheets
  If w.Name <> Me.Name Then w.AutoFilterMode = False
Next
'---filtrage---
If Me.AutoFilterMode Then
  If Me.AutoFilter.Filters(2).On Then 'filtre sur colonne B
    If Me.AutoFilter.Filters(2).Operator = 0 Then 'un seul critère
      crit = Me.AutoFilter.Filters(2).Criteria1
      For Each w In Worksheets
        If w.Name <> Me.Name Then _
          w.Range("A6:D" & w.[B65536].End(xlUp).Row).AutoFilter 2, crit
      Next
    End If
  End If
End If
End Sub

Le filtre est copié uniquement quand le filtrage est sur la colonne B avec un seul critère.

A+

 

[job75]

Re : tri sur plusieurs feuille

Re,

Par sécurité on peut ajouter ce test supplémentaire :

If Me.AutoFilter.Range.Column = 1 And _
  Me.AutoFilter.Range.Columns.Count > 1 Then 'sécurité

Il vérifie que le filtre est appliqué au moins sur les colonnes A et B.

Fichier (2).

A+

 

[rodge5895]

Re : tri sur plusieurs feuille

Bonjour et merci JOB75 pour votre réponse.
J'ai quelques bonnes connaissances sur Excel mais pas sur les macros, ce qui fait que j'arrive pas à interpréter la réponse !
Existe t il une réponse sans utiliser des macros ou quelle est la marche à suivre simple pour incorporer dans mon fichier la solution que vous avez proposée ?
D'avance merci
Rodge5895