Sub TriMoisJour()
Dim tablo, a(), b(), i&, dat, n&
tablo = [A1].CurrentRegion.Resize(, 2) 'matrice, plus rapide, au moins 2 éléments
ReDim a(UBound(tablo))
ReDim b(UBound(tablo))
For i = 2 To UBound(tablo)
dat = tablo(i, 1)
If IsDate(dat) Then
a(n) = Format(dat, "mm.dd.yyyy")
b(n) = CDbl(dat) 'convertit en nombre
n = n + 1
End If
Next
tri a, b, 0, n - 1
'---restitution---
If ActiveSheet.FilterMode Then ActiveSheet.ShowAllData 'si la feuille est filtrée
With [B2] '1ère cellule de destination, à adapter (ce peut être A2)
If n Then .Resize(n) = Application.Transpose(b) 'Transpose est limitée à 65536 lignes
.Offset(n).Resize(Rows.Count - n - .Row + 1).ClearContents 'RAZ en dessous
End With
End Sub
Sub tri(a, b, gauc, droi) ' Quick sort
Dim ref, g, d, temp
ref = a((gauc + droi) \ 2)
g = gauc: d = droi
Do
Do While a(g) < ref: g = g + 1: Loop
Do While ref < a(d): d = d - 1: Loop
If g <= d Then
temp = a(g): a(g) = a(d): a(d) = temp
temp = b(g): b(g) = b(d): b(d) = temp
g = g + 1: d = d - 1
End If
Loop While g <= d
If g < droi Then Call tri(a, b, g, droi)
If gauc < d Then Call tri(a, b, gauc, d)
End Sub