Transfert classeur "père" > classeur "fils" (VBA)

[nounbxl76]

Bonjour le forum,

Je viens une nouvelle fois vers vous car j'ai un gros problème à gérer… Il y a quelques temps, j'avais mis au point une base Excel qui me permettait de faire un suivi d'évènements… Aujourd'hui, mon boss a décidé de virer mon suivi "manuel" et a implémenté une base de données (http)... seulement, il me demande toujours de faire des indicateurs sur les évènements donc obligation de passer par Excel… Mon problème est donc simple… A partir d'une extraction de la base (fichier Excel) que j'appellerai "classeur fils", je souhaite alimenter un autre classeur que j'appellerai "classeur père". La procédure de rapatriement des données devant être réalisée à partir du "classeur père". Par ailleurs, avant d'être rapatriées, les données du "classeur fils" devront subir une petite beauté…
Ci-joint se trouvent les 2 classeurs pour plus de détails…
Pour le classeur fils, j'ai décortiqué ce qu'il doit subir sous forme de 3 onglets (avant modifications > modifications > après modification).
Pour le classeur père, j'ai mis avant/après.
A noter que cette procédure sera lancée tous les jours donc il faudra supprimer les données importées de la veille (supprimer les filtres + clearcontents)

Je ne sais pas si j'ai été très clair alors merci par avance à ceux qui se pencheront sur ce sujet.

Cordialement,

 

[Compte Supprimé 979]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Re,

Option Explicit

Sub tsfr2()
  Dim LigFin As Long  'DerLig As Long
  Dim i As Long, Nf As String, sPath As String
  Dim ShtFils As Worksheet, ShtPère As Worksheet
  Dim Inc As Integer, TabColS() As String, TabColD() As String


  Application.DisplayAlerts = False  ' Désactiver les alertes Excel
  Application.ScreenUpdating = False  ' Désactiver le rafraichissement d'écran


  ' Définir les tableaux des colonnes sources vers celles de destinations
  TabColS = Split("A,F,L,G,C,D,H,J,I", ",")
  TabColD = Split("A,B,C,D,E,F,G,H,I", ",")


  ' Définir la feuille de destination du classeur père
  Set ShtPère = ThisWorkbook.Sheets("Avant")


  ' Afficher toutes les données et les effacer
  On Error Resume Next  ' En cas d'erreur on continue
  With ShtPère
    .ShowAllData
    .Range("A17:I65000").ClearContents   'efface les anciennes données
  End With
  On Error GoTo 0  ' Remettre la gestion d'erreur à la normal


  ' Récupérer le nom entier du fichier
  sPath = ThisWorkbook.Path & "\"
  Nf = Dir(sPath & "\TW*.xls")


  ' Ouvrir le fichier
  Workbooks.Open Filename:=sPath & Nf, ReadOnly:=True


  ' Définir la feuille source
  Set ShtFils = ActiveWorkbook.Sheets(1)
  
  ' Trouver la ligne de fin
  LigFin = ShtFils.Range("A" & Rows.Count).End(xlUp).Row
  
  ' Activer ce classeur
  ShtPère.Activate
  
  ' Copier chaque plage indépendamment
  For Inc = 0 To 8
    ShtFils.Range(TabColS(Inc) & "5:" & TabColS(Inc) & LigFin).Copy
    ShtPère.Range(TabColD(Inc) & "17").PasteSpecial Paste:=xlPasteValues
    ' Si la colonne copiée est celle d'une date
    If Inc = 3 Or Inc = 5 Then
      ' Appliquer le format date à la colonne de destination
      ShtPère.Range(TabColD(Inc) & "17:" & TabColD(Inc) & 17 - 5 + LigFin).NumberFormat = "dd/mm/yyyy"
    End If
    ' Format nombre pour colonne des jours
    If Inc = 6 Then
      ShtPère.Range(TabColD(Inc) & "17:" & TabColD(Inc) & 17 - 5 + LigFin).NumberFormat = "0"
    End If
  Next Inc


  ' Fermer le classeur fils
  Workbooks(Nf).Close savechanges:=False


  ' Avec le classeur père
  With ShtPère
    .[A16].Sort Key1:=Sheets("Avant").[A17], Order1:=xlAscending, Header:=xlGuess  'tri
    [A17:A65000].SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow.Delete  '2).EntireRow.Delete
    Range("A17").Select
  End With


  Application.DisplayAlerts = True  ' Réactiver les alertes
  Application.ScreenUpdating = True  ' Réactiver le rafraichissement


End Sub

A+

 

[nounbxl76]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Bug sur le fichier résolu. Merci.
Par contre, la conversion de la date ne fonctionne pas.
Désolé pour le (méga) dérangement.

 

[Compte Supprimé 979]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Re,

Je ne sais pas ce qui ne va pas, chez moi ça fonctionne parfaitement !?

 

[nounbxl76]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Chez moi les dates présentes sous la colonne F (en-tête "Date current") sont sous le forme jj/mm/yyyy hh:mm:ss (ex pour la 1ère ligne : 06/01/2012 15:11:00) alors que j'aimerais qu'elles soient "jj/mm/yyyy". J'ai même essayé par Excel lui-même... format de cellule... mais rien n'y fait...

 

[Compte Supprimé 979]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Re,

Cela veut dire qu'Excel ne considère pas tes cellules comme des dates, mais du texte
Entre dans une cellule en mode saisie F2, puis valide pour voir

A+

 

[nounbxl76]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Re,

Quel est l'effet escompté?
Pour info, avant que la 1ère fois que le code a été appliqué, les données dates étaient transférées sous cette forme 40914,6326388889 ce qui me donne 06/01/2012 15:11:00 après changement de format...

 

[nounbxl76]

Re : Transfert classeur "père" > classeur "fils" (VBA)

Re,

Je viens de faire un petit test.. j'ai appliqué une MFC avec ESTNUM(cellule) sur tout le tableau... toutes les dates ont été mises en forme... je ne sais pas si ça peut aider mais bon...