Suprimmer les lignes qui contiennent..

[Guido]

Bonjour le Forum

Je reviens a nouveau pour une macro..

Dans cette feuille excel la colonnes B a des cellules comprenant des chiffres...

1 2 3 4 ou 5 .

J'aimerais gardé seulement les lignes qui ont le meme chiffres qui se trouve dans la cellule K1

Le contenu de la cellule K1 c'est moi qui le change selon que,,,

Merci pour votre aide

Voir le petit fichier

Merci

Guido

 

[Paf]

Re : Suprimmer les lignes qui contiennent..

Bonjour

S'il s'agit seulement de ne garder à l'affichage que les lignes comportant le N° choisi en cellule K1, le filtre automatique est tout indiqué.

S'il s'agit de supprimer définitivement les lignes, je réfléchis à une macro évènementielle (à la modif de K1) dès confirmation.

A+

 

[Guido]

Re : Suprimmer les lignes qui contiennent..

Hello paf

Je prefere une macro,car une autre macros feras un transfert dans une feuille

des lignes qui seront gardees

Merci

Guido

 

[laetitia90]

Re : Suprimmer les lignes qui contiennent..

bonjour tous 🙂🙂

un truc dans ce genre ??? a adapter

correctif... pas bon mal compris la qst

 

[Paf]

Re : Suprimmer les lignes qui contiennent..

Re,

Dans cette feuille excel la colonnes B a des cellules comprenant des chiffres...
1 2 3 4 ou 5 .

la colonne B ne contient pas que ces valeurs !

Dans le code de la feuille COURSE JOUABLES

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$K$1" Then
    Application.EnableEvents = False
    Application.ScreenUpdating = False
    With Worksheets("COURSE JOUABLES")
    Comp = .Range("K1")
    DerLig = .Range("B" & Rows.Count).End(xlUp).Row
    For i = DerLig To 2 Step -1
        If .Cells(i, 2) <> Comp Then ' si colonne B de la ligne en cours <> K1
            .Rows(i).Delete
            x = x + 1
        End If
    Next
    End With
End If
Application.EnableEvents = True
Application.ScreenUpdating = True
MsgBox x & "  lignes supprimée"
End Sub

version un peu lente, je regarde en passant par des tableaux

A+

 

[camarchepas]

Re : Suprimmer les lignes qui contiennent..

Bonjour à tous ,

Une autre solution pourrait être de trier par la colonne num
de rechercher par le haut la premiere occurence du nombre désiré dans num
de rechercher par le bas la derniere occurence du nombre désiré dans num

là 2 options soit l'on copie la zone premiere derniere occurence vers autre feuille
soit l'on delete derniere occurence + 1 derniere ligne
puis delete de 1ere ligne premiere occurence -1

 

[Modeste]

Re : Suprimmer les lignes qui contiennent..

Bonjour tout le monde,

Si l'objectif est de copier les données dans une autre feuille, pourquoi pas un filtre avancé 😕
Avec le n° de réunion en L2 et le titre "Reunion" en L1

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Target.Address <> "$L$2" Then Exit Sub
If Target = "" Then Exit Sub
[A1].CurrentRegion.AdvancedFilter Action:=xlFilterCopy, criteriarange:=[L1:L2], copytorange:=Sheets("Feuil1").[A1]
End Sub

 

[Guido]

Re : Suprimmer les lignes qui contiennent..

Ré

Dans cette feuille excel la colonnes B a des cellules comprenant des chiffres...


1 2 3 4 ou 5 .

la colonne B ne contient pas que ces valeurs !

mais dans 95% pour cent des cas oui..

A plus

Guido

 

[Guido]

Re : Suprimmer les lignes qui contiennent..

Re

Une erreur s'inscrit..

Sub Macro1()
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address = "$K$1" Then
Application.EnableEvents = False
Application.ScreenUpdating = False
With Worksheets("COURSE JOUABLES")
Comp = .Range("K1")
DerLig = .Range("B" & Rows.Count).End(xlUp).Row
For i = DerLig To 2 Step -1
If .Cells(i, 2) <> Comp Then ' si colonne B de la ligne en cours <> K1
.Rows(i).Delete
x = x + 1
End If
Next
End With
End If
Application.EnableEvents = True
Application.ScreenUpdating = True
MsgBox x & " lignes supprimée"
End Sub


macros est en couleur JAUNE...

Merci

 

[camarchepas]

Re : Suprimmer les lignes qui contiennent..

guido ,
le sub macro1() est en trop

 

[Guido]

Re : Suprimmer les lignes qui contiennent..

Re

ok merci ,je vais modifier

Guido

 

[DoubleZero]

Re : Suprimmer les lignes qui contiennent..

Bonjour, le Fil 😀, le Forum,

Un autre essai avec ce code :

Option Explicit
Sub Ligne_supprimer_si_valeur_différente()
    [b1].AutoFilter
    ActiveSheet.Range("a:j").AutoFilter Field:=2, Criteria1:="<>" & [k1]
    Rows("2:" & Rows.Count).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    [b1].AutoFilter
End Sub

A bientôt 🙂

 

[Guido]

Re : Suprimmer les lignes qui contiennent..

Bonsoir

Je dois vraiment mal m'y prendre

mais chaque fois ,j'ai un debogage...

Macros je suis pas doué..

a plus

Guido

 

[Robert]

Re : Suprimmer les lignes qui contiennent..

Bonsoir le fil, bonsoir le forum,

En pièce jointe ton fichier modifié avec la macro événementielle Change ci-dessous :

Private Sub Worksheet_Change(ByVal Target As Range) 'au changement dans l'onglet
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim PL As Range 'déclare la variable PL (PLage)
Dim PLV As Range 'déclare la variable PLV (PLage Visible)

If Target.Address <> "$K$1" Then Exit Sub 'si le changement a lieu ailleurs que dans la celllue K1, sort de la procédure
DL = Cells(Application.Rows.Count, 2).End(xlUp).Row 'définit la dernière ligne éditée Dl de la colonne 2 (=B)
Set PL = Range("B2:B" & DL) 'définit la plage PL
Range("A1").AutoFilter Field:=2, Criteria1:="<>" & Target.Value 'filtre la colonne B avec "<> K1" comme critères
Set PLV = PL.SpecialCells(xlCellTypeVisible) 'définit la plage PLV des cellules visibles de la plage PL (non filtrées)
PLV.EntireRow.Delete 'supprimes les lignes de la plage PLV
Range("A1").AutoFilter 'supprime le filtre automatique
End Sub

Le fichier :