Supprimer les doublons dans un tableau

[maval]

Bonjour,

Je cherche à créer une macro qui me permettrait supprimer les doublons sur 3 colonnes "A B C"
J'ai une tableau qui est alimentée par une macro et il arrive que certaines lignes soient doublées ou triplées ou quadruplées ...

Objectif: Quand il y a plusieurs fois le même enregistrement dans le tableau, je souhaiterais supprimer les enregistrements en trop mais garder la première ligne.
ci joint un modèle

Merci d'avance et bonne journée

 

[phlaurent55]

Re : Supprimer les doublons dans un tableau

Bonjour Max,

avec ceci:

    Range("A6").Select
    Selection.CurrentRegion.Select
    ActiveSheet.Range("$A$6:$C$48").RemoveDuplicates Columns:=1, Header:=xlNo

à+
Philippe

 

[Efgé]

Re : Supprimer les doublons dans un tableau

Bonjour maval
Une enième version :

Private Sub CommandButton1_Click()
Dim i&, L&, J%
Dim D As Object, TD As Variant, Tmp As Variant
Set D = CreateObject("Scripting.Dictionary")
With Sheets("Feuil1")
    TD = .Range(.Cells(6, 1), .Cells(.Rows.Count, 1).End(3)(1, 3))
    For i = 1 To UBound(TD, 1)
        Tmp = TD(i, 1) & TD(i, 2) & TD(i, 3)
        D(Tmp) = D(Tmp) + 1
        If D(Tmp) = 1 Then
            L = L + 1
            For J = 1 To 3
                TD(L, J) = TD(i, J)
            Next J
        End If
    Next i
    Application.ScreenUpdating = False
    With .Cells(6, 1)
        .Resize(UBound(TD, 1), UBound(TD, 2)).ClearContents
        .Resize(L, UBound(TD, 2)) = TD
    End With
End With
End Sub

CordialementEDIT Bonjour phlaurent55 , désolé, pas raffraichi ....

 

[maval]

Re : Supprimer les doublons dans un tableau

Bonjour Philippe, Efgé,

Je vous remercie et vous souhaite une très bonne journée.

Max