Microsoft 365 Suppression NA 2 conditions

[Lascaux]

Bonjour,


j'ai besoin de supprimer le contenu d'une cellule en fonction d'une condition.
dans mon exemple : si F2 =Oui je supprime le contenu de A2. (cela fonctionne sur l'exemple)
mais cela doit supprimer uniquement si A2 est égale à NA

et je dois faire ce test sur les colonnes A à E.

merci d'avance de votre aide.

 

[sylvanu]

Bonjour Lascaux, et bienvenu sur XLD,
Un essai en PJ avec :

Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Or Target.Value = "" Or Target.Value = "Non" Then Exit Sub
    If Not Intersect(Target, [F2:F1000]) Is Nothing Then
         Application.ScreenUpdating = False
         For C = 1 To 5
            If IsError(Cells(Target.Row, C)) Then Cells(Target.Row, C) = ""
         Next C
    End If
End Sub

La macro s'exécute lorsqu'on choisit Oui en colonne F.
Evidemment il faut activer les macros.

 

[oguruma]

Bonjour, ah pris de vitesse par sylvanu
mais une autre solution à toi de voir... il suffit d'y ajouter un bouton ou de l'actionner par le menu développeur

Sub DeleteNA()
Dim CurrentValue
Dim vCell As Range
Dim rRange As Range
Set rRange = Range("A1", Range("E1").End(xlDown))
For Each vCell In rRange
If Application.WorksheetFunction.IsNA(vCell) Then
If vCell.Offset(, 6 - vCell.Column) = "OUI" Then
vCell = ""
End If
End If
Next
End Sub

 

[job75]

Bonsoir,

@sylvanu sélectionne A3:B3 et efface... Faut corriger ça.

A+

 

[job75]

Avec le filtre automatique :

Sub Effacer()
Application.ScreenUpdating = False
With [A1:F1000]
    .AutoFilter 6, "Oui" 'filtre automatique
    On Error Resume Next
    .SpecialCells(xlCellTypeVisible).SpecialCells(xlCellTypeConstants, 16) = ""
    .AutoFilter 'ôte le filtre
End With
End Sub

 

[sylvanu]

Bonsoir Job,

sélectionne A3:B3 et efface... Faut corriger ça.

Rien compris.

Où est le problème ?

 

[oguruma]

Bonsoir,

@sylvanu sélectionne A3:B3 et efface... Faut corriger ça.

A+

Dans une 1ère version déposée sur le Forum... qui a subi une mauvaise recopie de code erroné, j'effaçais uniquement la colonne A
La nouvelle version corrigée est plus complète en balayant tout le tableau
A l'auteur du post en question d'adapter le code selon ses besoins mais l'essentiel est là !

 

[TooFatBoy]

Bonjour,

Rien compris.

Il dit : tu sélectionnes la plage A3:B3 avec ta souris, puis tu appuies sur la touche <Suppr> et là ça bug, mas il suffit de couper la première ligne de la macro en deux pour corriger le problème. 😉

 

[oguruma]

Bonjour,


Il dit : tu sélectionnes la plage A3:B3 avec ta souris, puis tu appuies sur la touche <Suppr> et là ça bug, mas il suffit de couper la première ligne de la macro en deux pour corriger le problème. 😉

Et pourquoi ne pas faire une suppression à la demande en définissant une plage dynamique comme je l'ai fait ou tout simplement une plage statique... ça nous évite du code dans feuille et la gestion évènementielle. Du reste on ignore l'origine des données et ce qui a provoqué ce #N/A... Cette fonction de suppression doit être initiée manuellement car nous avons une de décision OUI/NON => colonne F

 

[TooFatBoy]

Et pourquoi ne pas faire une suppression à la demande en définissant une plage dynamique comme je l'ai fait ou tout simplement une plage statique...

Je ne comprends pas ce que tu proposes. Mais peu importe, je ne faisais qu'expliquer à sylvanu ce qu'il disait ne pas avoir compris dans le message laconique de job75.

 

[job75]

J'attendais qu'on me dise de mettre On Error Resume Next.

Avant d'aller dormir je viens de le faire.

Bonne nuit.

 

[Lascaux]

Top merci. la solution de sylvanu correspond parfaitement.

 

[sylvanu]

Re,
Pour éviter cette possibilité d'erreur ( sélection de toute la ligne puis Supp ) autant l'éviter :

Sub Worksheet_Change(ByVal Target As Range)
On Error GoTo Fin
    If Target.Value = "" Or Target.Value = "Non" Then Exit Sub
    If Not Intersect(Target, [F2:F1000]) Is Nothing Then
         Application.ScreenUpdating = False
         For C = 1 To 5
            If IsError(Cells(Target.Row, C)) Then Cells(Target.Row, C) = ""
         Next C
    End If
Fin:
End Sub