Suppression de valeurs

[claude43]

Bonjour le Forum,

Dans la plage de valeurs A1:E22, soit sur 5 colonnes, comment effacer les valeurs 10 et 43 qui apparaissent
dans chaque ligne ? Pour obtenir de manière rangée le tableau H1:J22 réduit en 3 colonnes.

Merci

Ci-joint le travail

 

[claude43]

Re : Suppression de valeurs

Re bonjour,

J'ai réussi a faire disparaitre les valeurs 10 et 43 par la formule :=SI(A1=10;"";SI(A1=43;"";SI(ESTNONTEXTE(A1);A1)))
mais pour l'instant j'ai pas réussi à ordonner le résultat !!

A bientôt

 

[david84]

Re : Suppression de valeurs

Bonjour,
formule matricielle (valider par Ctrl, Maj et entrée) à tester :

=SIERREUR(INDEX($A1:$E1;PETITE.VALEUR(SI(($A1:$E1<>10)*($A1:$E1<>43);COLONNE($A1:$E1));COLONNE(A:A)));"")

A+

 

[claude43]

Re : Suppression de valeurs

Bonjour David,

Merci pour ton aide, la formule est sans effet !!

A + Claude

 

[david84]

Re : Suppression de valeurs

Bonjour David,

Merci pour ton aide, la formule est sans effet !!

A + Claude

Elle fonctionne chez moi.
C'est une formule matricielle : elle doit être validée via les touches Ctrl, Maj et Entrée puis être tirée vers la droite et le bas.
A+

 

[tototiti2008]

Re : Suppression de valeurs

Bonjour claude, David 🙂,

SIERREUR n'existait pas en Excel 2000

=SI(ESTERREUR(INDEX($A1:$E1;PETITE.VALEUR(SI(($A1:$E1<>10)*($A1:$E1<>43);COLONNE($A1:$E1));COLONNE(A:A))));"";INDEX($A1:$E1;PETITE.VALEUR(SI(($A1:$E1<>10)*($A1:$E1<>43);COLONNE($A1:$E1));COLONNE(A:A))))

 

[claude43]

Re : Suppression de valeurs

Re salut David :

J'ai bien fait Ctrl, Maj puis Entrée, ça affiche "#NOM?"
Il est vrai que je fais ce travail sur un Excel antique : "Excel 97" mais jusqu'a présent je n'ai jamais eu de problème avec les formules
sur ce forum !

Je vais encore controler si il y a une faille quelque part !

A bientôt

 

[david84]

Re : Suppression de valeurs

Salut mon tototiti !
ben je n'avais pas vu !
Autre possibilité :

=SI(COLONNE(A:A)>SOMME(($A1:$E1<>10)*($A1:$E1<>43));"";INDEX($A1:$E1;PETITE.VALEUR(SI(($A1:$E1<>10)*($A1:$E1<>43);COLONNE($A1:$E1));COLONNE(A:A))))

Ou s'il y a toujours 3 colonnes :

=SI(COLONNE(A:A)>3;"";INDEX($A1:$E1;PETITE.VALEUR(SI(($A1:$E1<>10)*($A1:$E1<>43);COLONNE($A1:$E1));COLONNE(A:A))))

A+

 

[claude43]

Re : Suppression de valeurs

Bonsoir Tototiti2008, David,

Ouf ! C'était bien un problème de syntaxe méconnu par mon cher ancêtre.

Ca fonctionne parfaitement.

Merci pour votre aide

Claude