sous total suite

[peg63]

bonsoir,
je reviens à la charge avec mon sous total avec filtre sur deux colonnes (au lieu d'une)
ci-joint fichier qui vaudra mieux qu'un long discours
merci d'avance

 

[Tibo]

Re : sous total suite

Bonjour,

Sous réserve d'avoir bien compris ton souhait, un essai avec une formule déjà proposée par JCGL dans ton fil précédent :

=SOMMEPROD((SOUS.TOTAL(3;DECALER(B5:B11;LIGNE(B5:B11)-MIN(LIGNE(B5:B11));;1)))*(C5:C11))

Je te laisse tester

@+

 

[job75]

Re : sous total suite

Bonjour peg63, salut Tibo,

Je crois que la formule précédente est de moi, Tibo 🙂 Mais peut-être que JC l'avait trouvée avant, auquel cas ce sera avec plaisir que je lui en laisserai la paternité.

Quant au problème posé, formule en C13 :

=SOMMEPROD((NB.SI(DECALER(B5;;;LIGNE(B5:B11)-4);SOUS.TOTAL(9;DECALER(B5;LIGNE(B5:B11)-5;)))=1)*C5:C11)

Fichier joint.

Edit : du coup j'ai complété le fil précédent :

https://www.excel-downloads.com/threads/sous-total-avec-condition.165495/

A+

 

[peg63]

Re : sous total suite

bonsoir je viens de prendre le message et merci
mais la formule n'est pas au point car lorsque je trie sur une autre varieté ex l je devrai avoir 8 et j'obtiens 0
encore un petit truc à trouver on est pas loin
j'attends avec impatiente je cherche de mon coté
a+

 

[job75]

Re : sous total suite

Bonjour peg63, le forum,

La formule avec NB.SI va bien sur l'autre fil car toutes les cellules d'une même zone sont affichées.

Ici en effet ça ne va pas. Alors cette autre solution :

1) Définir (menu Insertion-Nom) le nom Matrice par :

=SOUS.TOTAL(9;DECALER('Feuil1 (2)'!$B$5;LIGNE('Feuil1 (2)'!$B$5:$B$11)-5;))

2) Formule en C13 :

=SOMMEPROD((LIGNE(B5:B11)=4+(Matrice>0)*EQUIV(Matrice;Matrice;0))*C5:C11)

Fichier (2).

A+

 

[peg63]

Re : sous total suite

super !!! ça marche et respect job 75 c'était pas facile je pense
merci et à +