sommeprod et doublon

[mix770]

bonsoir,
je retente ma demande,
dans mon tableau je compte le nombre de personnes suivant des critères: (=SOMMEPROD(('FORMATIONS PREVUES'!$B$2:$B$666="statutaire")*('FORMATIONS PREVUES'!$F$2:$F$666="homme")*('FORMATIONS PREVUES'!$H$2:$H$666="maîtrise"))
j'ai besoin de savoir le nombre de personnes concernées donc je vais chercher dans la colonne "D" avec les noms mais je ne sais pas comment l'intégrer dans le reste de la formule
merci a vous je suis à la ramasse
cordialement

 

[mutzik]

Re : sommeprod et doublon

bonjour

essaie
=SOMMEPROD(('FORMATIONS PREVUES'!$B$2:$B$666="statutaire")*('FORMATIONS PREVUES'!$F$2:$F$666="homme")*('FORMATIONS PREVUES'!$H$2:$H$666="maîtrise")*1)

 

[mix770]

Re : sommeprod et doublon

bonsoir,
merci pour ta réponse cela fonctionne mais il me donne "5" ce qui est bien le nombre de stages, ce que je souhaite c'est connaitre le nombre de personnes qui partent en stage en filtrant a la mimine je trouve 3 "paul 2, marc 2, regis 1" il faut chercher sur la colonne D je pense celle des noms de famille ce qui trie les doublons
merci a toi

 

[Habitude]

Re : sommeprod et doublon

Bonjour

A tester, remplacer le *1 par
*('FORMATIONS PREVUES'!$D$2:$D$666)

Pour avoir une zone dynamique et non statique '666
Regarde du coté de Indirect et nbval

 

[mix770]

Re : sommeprod et doublon

bonjour,
cela ne marche pas, nous sommes sur la bonne voie je pense car on n'indique pas une référence à compter 'homme', mais un nombre de lignes sans doublons après filtrage des 3 premiers critères
cordialement

 

[job75]

Re : sommeprod et doublon

Bonjour mix770, mutzik, Habitude,

Utiliser NB.SI dans SOMMEPROD pour éliminer les doublons :

=SOMMEPROD(('FORMATIONS PREVUES'!$B$2:$B$666="statutaire")*('FORMATIONS PREVUES'!$F$2:$F$666="homme");('FORMATIONS PREVUES'!$H$2:$H$666="maîtrise")*(NB.SI(DECALER($D$2;;;LIGNE($D$2:$D$666));$D$2:$D$666)=1))

Nota : les signes $ ne sont pas nécessaires si la formule n'a pas besoin d'être tirée.

Edit : petit détail pour les gens minutieux.

J'ai mis un ; au milieu à la place d'un * car il occupe 1 octet au lieu de 2 😎

Les 2 autres * de part et d'autre sont indispensables pour obtenir des nombres...

A+

 

[Monique]

Re : sommeprod et doublon

Bonjour, et meilleurs vœux à tous

Un essai avec Frequence

=SOMME((FREQUENCE(SI(('FORMATIONSPREVUES'!$B$2:$B$666="statutaire")*('FORMATIONSPREVUES'!$F$2:$F$666="Homme")*('FORMATIONSPREVUES'!$H$2:$H$666="Maîtrise");EQUIV('FORMATIONSPREVUES'!$D$2:$D$666;'FORMATIONS PREVUES'!$D$2:$D$666;0));LIGNE('FORMATIONSPREVUES'!$D$1:$D$666))>0)*1)

Formule matricielle, à valider par ctrl, maj et entrée

 

[mix770]

Re : sommeprod et doublon

Bonjour,
merci à toi, j'admire le sens du détail 😎, effectivement le $ ne sert à rien dans mon cas, ta formule fonctionne du tonnerre, je l'ai testée sur l'onglet ou sont les données 'formations prévues', et quand je le mets dans le tableau à l'onglet effectif, j 'ai ajouté 'formations prévues' merci beaucoup à toi.
=SOMMEPROD(('FORMATIONS PREVUES'!$B$2:$B$666="statutaire")*('FORMATIONS PREVUES'!$F$2:$F$666="homme");('FORMATIONS PREVUES'!$H$2:$H$666="maîtrise")*(NB.SI(DECALER('FORMATIONS PREVUES'!$D$2;;;LIGNE('FORMATIONS PREVUES'!$D$2:$D$666));'FORMATIONS PREVUES'!$D$2:$D$666)=1))

et si je voulais compter le nombre de stages en plus des autres critères cela marcherai ? et quelle formules serait appropriée

un grand merci et respect pour la maitrise

 

[job75]

Re : sommeprod et doublon

Bonjour mix770, salut Monique,

Effectivement j'avais oublié de préciser la feuille dans NB.SI.

et si je voulais compter le nombre de stages en plus des autres critères cela marcherai ? et quelle formules serait appropriée

Si à chaque stage correspond un nom, le nombre total de stages est :

=NBVAL('FORMATIONS PREVUES'!D2:D666)

Donc si j'ai bien compris la question, le nombre de stages en plus des autres critères (?) est donné par :

=NBVAL('FORMATIONS PREVUES'!D2:D666)-SOMMEPROD(('FORMATIONS PREVUES'!B2:B666="statutaire")*('FORMATIONS PREVUES'!F2:F666="homme");('FORMATIONS PREVUES'!H2:H666="maîtrise")*(NB.SI(DECALER('FORMATIONS PREVUES'!D2;;;LIGNE('FORMATIONS PREVUES'!D2:D666));'FORMATIONS PREVUES'!D2:D666)=1))

A+

 

[mix770]

Re : sommeprod et doublon

bonsoir à tous,
merci Monique et à tous, et tu as raison Monique bonne année à tous, avec plein de bonheur et de grattage de tête devant nos tableaux excel, j'adooooore ça !!
alors oui job75, c'est un critère de plus, la formule me semble intéressante ainsi que celle de Monique, j'ai oublié ma clé USB avec le fichier dessus au bureau, je fais le test demain et vous tiens informé
bonne soirée, et merci à tous c'est cool
très cordialement