Somme sur une plage donnée sous condition

[Fab117]

Salut,
Sur une plage donnée
p. ex. : =SUM(H7:H27)
je voudrais qu'il n'additionne que les valeurs comprises dans l'intervale :
[1250;1350[
Quelqu'un pourrait-il svp m'indiquer la formule à utiliser ?
Merci.

Fab

 

[SergiO]

Re : Somme sur une plage donnée sous condition

Bonjour Fab,

Essaie comme ceci :

=SUMPRODUCT((H7:H27>=1250)*(H7:H27<1350);H7:H27)

@+

 

[Dan]

Re : Somme sur une plage donnée sous condition

Bonjour,

On peut aussi utiliser cette formule :

{=SOMME((H7:H27>=1250)*(H7:H27<1350)*H7:H27)}

Formule matrielle à valider par CTRL+SHIFT+ENTER

A bientôt

Dan

 

[Fab117]

Re : Somme sur une plage donnée sous condition

Merci à vous deux et bon week-end.

Fab

 

[Fab117]

Re : Somme sur une plage donnée sous condition

Salut,
En fait en y regardant de plus près, ce dont j'aurais besoin, c'est de sommer non pas les valeurs comprises dans l'intervale [1250;1350[ mais celles de la colonne voisine.
En plus clair, à chaque fois qu'il recontre dans la colonne A une valeur comprise dans l'intervale [1250;1350[, il rajoute la valeur contenue dans la colonne B au total intermédiaire.
Comme je ne me sens toujours pas clair, ci-joint un fichier exemple.

Fab

 

[wilfried_42]

Re : Somme sur une plage donnée sous condition

Bonjour fab117

Voici une formule

=SOMMEPROD($B$2:$B$13*(($A$2:$A$13>=CNUM(GAUCHE(F2;4)))=($A$2:$A$13<CNUM(DROITE(F2;4)))))

 

[Fab117]

Re : Somme sur une plage donnée sous condition

Merci Wilfried_42.
Aurais-tu stp l'équivalence pour Excel version anglaise ?

Fab

 

[SergiO]

Re : Somme sur une plage donnée sous condition

Bonjour Fab, Wilfried,

La formule de Wilfried en anglais :

=SUMPRODUCT($B$2:$B$13*(($A$2:$A$13>=VALUE(LEFT(F2 ;4)))=($A$2:$A$13<VALUE(RIGHT(F2;4)))))

@+

 

[Fab117]

Re : Somme sur une plage donnée sous condition

Salut,
Je ne comprend pas cette formule, mais elle fonctionne parfaitement.
Merci.

Fab

 

[Monique]

Re : Somme sur une plage donnée sous condition

Bonjour,

Ou bien ça :
=SOMMEPROD($B$2:$B$13*($A$2:$A$13>=GAUCHE($F2;4)*1=($A$2:$A$13<DROITE($F2;4)*1)))

=SUMPRODUCT($B$2:$B$13*($A$2:$A$13>=LEFT($F2,4)*1=($A$2:$A$13<RIGHT($F2,4)*1)))

*1 ou /1 ou +0 ou -0

Ou bien aussi :
=SOMMEPROD($B$2:$B$13*($A$2:$A$13>=--GAUCHE($F2;4)=($A$2:$A$13<--DROITE($F2;4))))

=SUMPRODUCT($B$2:$B$13*($A$2:$A$13>=--LEFT($F2,4)=($A$2:$A$13<--RIGHT($F2,4))))