Somme sur onglets précédents

[Stupidophil]

Bonjour à tous,

voici mon problème:
j'ai un fichier planning avec 52 onglets, représentant chacun une semaine de l'année.
A la fin, j'ai notamment un récapitulatif qui somme les données entrées dans une cellule de chaque onglet.
La formule est:
=SOMME('Semaine 1:Semaine 51'!J16)
Impeccable, ça me somme les 52 cases.

Mais j'aimerais affiner le truc.
Je voudrais que (par exemple) sur l'onglet "semaine 12", dans une cellule, Excel me somme la cellule en question avec les cellules des onglets PRECEDENTS.
En gros, j'aimerais trouver une formule qui dit à Excel de sommer la cellule J16 des onglets "Semaine 1" à "Semaine (en cours)"

Pour ajouter un poil de difficultés, cette formule doit être facile à mettre en place... effectivement, ce calcul sera présent 9 fois sur chaque onglet (un calcul sur les cellules J4, un sur les J6, un sur les J8... jusqu'à J18) et ce, sur les 52 onglets.... alors si il faut que je retape 468 la nouvelle formule, en la modifiant à chaque fois, ça peut être pénible...🙁

Merci d'avance à tous ceux qui pourraient faire avancer mon schmilblick 🙂

 

[hoerwind]

Re : Somme sur onglets précédents

Bonjour,

Dans une cellule de chaque feuille tu peux, par formule, récupérer le nom de l'onglet de cette feuille.
Tu peux également, toujours dans la même cellule, concaténer le nom de l'onglet de la première feuille avec le nom de l'onglet récupéré par formule, pour faire 'Semaine 1':'Semaine12'!.

Ensuite, pour faire la somme tu fais appel à la fonction INDIRECT qui fait référence à la cellule contenant la concaténation et en y ajoutant la référence de la cellule dont tu souhaites faire la somme.

Si tu ne vois pas comment faire, fais signe, je te ferai un exemple.

 

[job75]

Re : Somme sur onglets précédents

Bonjour Stupidophil, hoerwind,

Voyez le fichier joint avec les formules en C1 et E1 qui utilisent la fonction DECALERFEUILLE.

Pour que cette fonction fonctionne, il faut télécharger sur le web (c'est gratuit) la macro complémentaire Morefunc.

C'est une bibliothèque de fonctions.

A+

 

[Stupidophil]

Re : Somme sur onglets précédents

Merci Hoerwind et Job75 pour vos réponses.
Je préfère ne pas avoir à ajouter de fonction supplémentaire à télécharger. En effet, ce fichier est utilisé dans mon entreprise, sur plusieurs postes.
Ca serait donc plus facile de se cantonner à une fonction incluse dans Excel 😉

Je viens d'essayer de faire ce que je veux faire avec INDIRECT... mais je me mélange un peu les pinceaux....
Hoerwind, tu peux m'aiguiller?

 

[BOISGONTIER]

Re : Somme sur onglets précédents

Bonjour,

Formules Matricielles 3D

JB

 

[Stupidophil]

Re : Somme sur onglets précédents

Meric Boisgontier... mais j'ai beau essayé d'adapter les formules données sur ton lien, je n'ai que des #NOM ou #REF comme résultat.... j'arrive pas à transformer les formules pour mon cas

 

[mutzik]

Re : Somme sur onglets précédents

bonjour la clique, Stupidophil

vois dans l'exemple si cela te convient

 

[job75]

Re : Somme sur onglets précédents

Re,

Une autre solution avec des noms définis (menu Insertion-Nom) utilisant des fonctions macros Excel 4.0 :

- Position => =LIRE.DOCUMENT(87)

- FeuillePrecedente => =INDEX(LIRE.CLASSEUR(1);Position-1)

Voir les formules en C1 et E1 du fichier.

A+

 

[Stupidophil]

Re : Somme sur onglets précédents

Merci à tous pour vos réponses.
J'ai fait quelques essais, mais c'est toujours pas ça qu'est ça...
Je reste sur l'idée de faire ça avec INDIRECT...
J'ai par exemple une formule qui permet de récupérer la date de la feuille précédente pour afficher la date adéquate:
=INDIRECT("'Semaine " & DROITE(CELLULE("nomfichier";A1);2)-1 & "'!c3")+7
Ca marche bien.
J'aurais donc aimé, par soucis de cohérence, rester sur ce même genre de formule.
En gros il faudrait que je trouve un truc du style:
§§§ = le nom de la feuille, c'est à dire le nom de la Semaine en cours
SOMME ("Semaine 1"!J16:"§§§"!:J16)
euh... en gros, c'est ce que je souhaiterais obtenir... pas sûr que mon exemple soit très clair...

 

[mutzik]

Re : Somme sur onglets précédents

re, non en effet, pas trop clair (t'as regardé mon fichier ?)
sinon, faut nous joindre ton fichier en y mettant ce que tu attends exactement

 

[Stupidophil]

Re : Somme sur onglets précédents

Mutzik, oui j'ai regardé ton fichier. C'est à peu près ce que je cherche, mais pas tout à fait.
Je me casse les dents sur la formule:
SOMME('Semaine 1:Semaine_en_cours'!J4)
Je cherche comment faire pour qu'Excel, dans la formule, me mette automatiquement Semaine_en_cours...
Parce que si je tape à la main:
=SOMME('Semaine 1:Semaine 3'!J4)
ça fonctionne nickel, et c'est ce que je veux.
Mais, je voulais automatiser le truc en faisant en sorte qu'Excel me trouve le nom de la feuille en cours

 

[job75]

Re : Somme sur onglets précédents

Re,

Oui, avec la fonction CELLULE :

- en C1 (à partir de Semaine 2) :

=INDIRECT("'"&"Semaine "&DROITE(CELLULE("FileName";C1);2)-1&"'!C"&LIGNE())+A1

- ou en E1 (pour toutes les semaines) :

=SI(DROITE(CELLULE("FileName";E1);2)<>" 1";INDIRECT("'"&"Semaine "&DROITE(CELLULE("FileName";E1);2)-1&"'!C"&LIGNE()))+A1

Fichier joint.

Edit : on peut supprimer "'"& en mettant l'apostrophe juste devant le S de "Semaine "...

A+

 

[job75]

Re : Somme sur onglets précédents

@ stupidophile :

On a bien compris ce que vous souhaitez faire, mais ça ne marchera pas.

Le nom de la feuille en cours est donné par :

="Semaine "&SUPPRESPACE(DROITE(CELLULE("FileName";C1);2))

Mais en l'introduisant dans la fonction INDIRECT ça ne marchera pas, car :

=SOMME(INDIRECT("'Semaine 1:Semaine 3'!A1"))

=SOMME(INDIRECT("'Semaine 1'!A1:'Semaine 3'!A1"))

ne fonctionnent ni l'une ni l'autre...

A+

 

[Stupidophil]

Re : Somme sur onglets précédents

Merci Job75 pour les réponses,
En fait j'y suis arrivé! Et ce grâce à toi (euh, "à vous" au choix).
J'ai repris la formule citée plus haut et l'ai mise à ma sauce:
=INDIRECT("'"&"Semaine "&DROITE(CELLULE("FileName";K5);2)-1&"'!K"&LIGNE())+J4
Ca fonctionne. J'ai plus qu'à remettre ça en forme dans mon classeur.
Encore emrci

 

[job75]

Re : Somme sur onglets précédents

Re,

Pour terminer, en utilisant la fonction SOMMEPROD, je pense qu'on aura fait le tour de la question.

On n'utilise plus alors la feuille précédente, mais toutes les feuilles précédentes.

Formule en C1 du fichier joint :

=SOMMEPROD(N(INDIRECT("'Semaine "&LIGNE(INDIRECT("1:"&SUPPRESPACE(DROITE(CELLULE("FileName";C1);2)))) &"'!A"&LIGNE())))

Edit : bien noter la fonction N() qui est indispensable.

A+