Somme sous condition

[Dedn]

Bonjour,

Voilà j'ai un problème sur un fichier que j’essaie de mettre en place.
Sur un planning du mois d'aout , les samedis et les dimanches sont sous forme conditionnelle.
Jusque la tout va bien, seulement j'aimerai comptabiliser les samedis et les dimanches d'une part.

j'ai essayé de faire somme avec couleurselct, problème excel me calcul le tout .
Pouvez-vous m'aider ?

Je vous joins mon fichier pour mieux visualiser.

 

[Monique]

Re : Somme sous condition

Bonjour,

Le format conditionnel :
=JOURSEM(C$8;2)=6 --> beige
=JOURSEM(C$8;2)=7 --> jaune

Nb de samedis
=SOMMEPROD((JOURSEM($C$8:$AG$8;2)=6)*1)
Nb de dimanches
=SOMMEPROD((JOURSEM($C$8:$AG$8;2)=7)*1)
Nb de samedis et dimanches
=SOMMEPROD((JOURSEM($C$8:$AG$8;2)>5)*1)

 

[Dedn]

Re : Somme sous condition

Bonjour,

Merci mais ce n'est pas le nombre de samedi et de dimanche que je recherche à calculer.
Je me suis mal exprimé

Le premier tableau es un planning au cours du mois qui retrace les horaires effectués par l'équipe (a1, a2 ou d1, d2)
le second comptabilise le total d'heure effectué.
J'aimerai par ma mise en forme conditionnelle faire la somme des heures effectués pour les jours ouvrés, les samedi et les dimanches .

 

[Monique]

Re : Somme sous condition

Bonjour,

Si tu veux compter les couleurs par macro, je ne sais pas faire
Quelqu'un viendra répondre à ton message

Par contre, si tu ne veux pas que les mois de 28, 29 ou 30 jours se terminent le mois suivant,
tu mets cette formule en D8 et tu recopies vers la droite :

=SI(C8="";"";SI(MOIS(C8+1)<>MOIS(C8);"";C8+1))

 

[JBOBO]

Re : Somme sous condition

Bonjour,

pour le calcul des heures en C26 à tirer vers le bas :

=SOMMEPROD((JOURSEM($C$8:$AG$8;2)<6)*($C9:$AG9))

,
en D26 à tirer vers le bas :

=SOMMEPROD((JOURSEM($C$8:$AG$8;2)=6)*($C9:$AG9))

et en E26 à tirer vers le bas :

=SOMMEPROD((JOURSEM($C$8:$AG$8;2)=7)*($C9:$AG9))