SOMME.SI.ENS avec conditions sur une plage de dates

[isam1984]

Bonjour à tous,

Je cherche à mesurer une performance de délai de traitement d'appels d'offres clients partir d'un fichier disposant des informations suivantes entre les lignes 3 et 52 : (cf Feuille 1 du fichier en PJ)

Colonne A: Date de réception de l'appel d'offre
Colonne B: Objectif de date de remise d'offre
Colonne C: Calcul du délai restant entre date du jour et objectif de date de remise d'offre
Colonne D: Date de remise d'offre
Colonne E: Calcul de la performance (écart entre colonne B et colonne D)
Colonne F: Etat (On-Time / Late) en fonction du résultat de la colonne E


En l'occurrence, ce que je souhaite faire (cf Feuille 2 du fichier en PJ), c'est mesurer pour le mois de février le nombre d'offre remises à l'heure. Je souhaite donc vérifier les conditions suivantes :

Colonne D = Février
Colonne F = "On-Time"

Pour cela j'utilise la formule suivante :

=SOMME.SI.ENS('Base DDP'!$F$3:$F$52;'Base DDP'!$D$3:$D$52;">"&DATE(ANNEE(C4);MOIS(C4);0);'Base DDP'!$D$3:$D$52;">"&DATE(ANNEE(C4);MOIS(C4)+1;0);'Base DDP'!$F$3:$F$52;"On-Time")


Mon problème c'est que le résultat est toujours à 0...


Pourriez-vous m'indiquer ce qui bloque ?

Je vous remercie beaucoup pour l'aide que vous pourrez m'apporter pour débloquer cette situation sur laquelle je me suis creusé les méninges pendant plusieurs heures déjà...

Bonne journée,

 

[chris]

Re : SOMME.SI.ENS avec conditions sur une plage de dates

Bonjour

2 erreurs :

• recherche de "On time" sur la mauvaise colonne
• la date supérieure au 28/02 ne peut rien renvoyer

=SOMME.SI.ENS('Base DDP'!$E$3:$E$52;'Base DDP'!$D$3:$D$52;">"&DATE(ANNEE(D4);MOIS(D4);0);'Base DDP'!$D$3:$D$52;"<="&DATE(ANNEE(D4);MOIS(D4)+1;0);'Base DDP'!$F$3:$F$52;"On-Time")

devrait mieux correspondre

 

[isam1984]

Re : SOMME.SI.ENS avec conditions sur une plage de dates

Bonjour,

Merci beaucoup pour votre réponse. Effectivement, en créant mon fichier exemple que j'ai mis en PJ, j'ai mal recopié la formule.

Par contre, la somme que je cherche à faire porte bien sur la colonne F et non sur la colonne E. Je cherche à connaître le nombre d'offres remises "On-Time" (46 sur 50 dans mon exemple). La colonne E correspond au nombre de jour entre la date souhaitée et la date réalisée. Elle me permettra ensuite de calculer un nombre moyen de jours de retard pour les offres en retard.

Ainsi, si j'utilise la formule proposée, je trouve 40 (au lieu de 46). Le 40 correspond au total du nombre de jour "d'avance" avec lequel ont été remises les offres "On-Time".

 

[chris]

Re : SOMME.SI.ENS avec conditions sur une plage de dates

Re


On ne peut faire de somme sur des textes : voir si NB.SI.ENS n'est pas plus approprié...

=NB.SI.ENS('Base DDP'!$D$3:$D$52;">"&DATE(ANNEE(D4);MOIS(D4);0);'Base DDP'!$D$3:$D$52;"<="&DATE(ANNEE(D4);MOIS(D4)+1;0);'Base DDP'!$F$3:$F$52;"On-Time")

 

[isam1984]

Re : SOMME.SI.ENS avec conditions sur une plage de dates

Excellent.

Avec la fonction NB.SI.ENS cela fonctionne parfaitement.

Merci beaucoup