Somme si..... Alors

[isquiv94]

Bonjour,

J'ai une formule :

=((RECHERCHEV(B17;'TARIF MODIVIA RESEAU.xls'!toto;6;FAUX))*(1-$E$3))*(1-$E$4)*(1-$E$5)*(1-$E$6)

Elle me donne un prix en partant d'un tarif de base que multiplie des remises en cascade.

Je souhaite ajouter encore une remise en cascade (g7), seulement si dans la a7, il y a OUI d'écrit.

Comment faire ?

D'avance merci de votre aide🙂

 

[Guest]

Re : Somme si..... Alors

bonjour à toutes et tous,

Suis pas le meilleur en formule mais peut-être cela le fera:

=((RECHERCHEV(B17;'TARIF MODIVIA RESEAU.xls'!toto;6;FAUX))*(1-$E$3))*(1-$E$4)*(1-$E$5)*(1-$E$6)*SI($A$7="OUI";1-$G$7;1)

A+

 

[bpol]

Re : Somme si..... Alors

bonjour isquiv et hasco,

a essayer:

=si(G7="OUI3;1-$G$7;((RECHERCHEV(B17;'TARIF MODIVIA RESEAU.xls'!toto;6;FAUX))*(1-$E$3))*(1-$E$4)*(1-$E$5)*(1-$E$6))

A+
Bpol

 

[isquiv94]

Re : Somme si..... Alors

Trop Top Hasco, mais....

Si dans ma même cellule A7, c'est écrit non, et donc ça veut dire que je ne veux pas que le pourcentage de la cellule G7 s'applique, comment je fais ?

 

[Guest]

Re : Somme si..... Alors

Re,


As-tu essayé?

Normalement la formule multipliera par 1 le résultat déjà obtenu avant le test, ce qui n'y changera rien.

Si A7 = Oui Multiplier par 1-G7 sinon Multiplier par 1


A+

 

[isquiv94]

Re : Somme si..... Alors

Oui, Hasco, j'ai essayé ta formule :

=((RECHERCHEV(B17;'TARIF MODIVIA RESEAU.xls'!toto;6;FAUX))*(1-$E$3))*(1-$E$4)*(1-$E$5)*(1-$E$6)/SI($A$7="OUI";1-$G$7;0),

mais si dans A7, je mets NON, alors mon résultat est "DIV/0!"

Donc ça va pas

Tu peux encore m'aider ?

Merci

 

[Monique]

Re : Somme si..... Alors

Bonjour,

Ou bien
=Recherchev(etc)*(1-$E$3)*(1-$E$4)*(1-$E$5)*(1-$E$6)*(1-$G$7*($A$7="oui"))

Pour raccourcir mais à valider par ctrl, maj et entrée :
=Recherchev(etc)*PRODUIT(1-$E$3:$E$6)*(1-$G$7*($A$7="oui"))

 

[Guest]

Re : Somme si..... Alors

RE,

bonjour la Championne, Heureux de te retrouver.😀

A+++

 

[isquiv94]

Re : Somme si..... Alors

Monique,

Je sais pas dans quoi je me suis embarquée...

Merci, ta formule marche seulement le résultat n'est pas bon et je ne comprend pas pourquoi.

De plus, ma formule si, doit s'appliquer sur les deux conditions en A7 et A8.

Autant les lignes de 3 à 4 sont des remises, alors que 7 et 8 sont des majorations.

J'ai téléchargé un extrait de mon fichier en pièce jointe. Si vous pouviez m'aider, ce serait super. La version excel est supérieure à ce que le site autorise, c'est pour celà que j'ai fait une copie écran

Merci

 

[isquiv94]

Re : Somme si..... Alors

Monique,

J'ai refait des essais. Je n'ai plus de problème de calcul, mais je n'arrive pas à faire le résultat sur les deux variantes :

=((RECHERCHEV(D17;'TARIF MODIVIA RESEAU.xls'!toto;6;FAUX))*PRODUIT(1-$E$3:$E$6)*(1+$G$7*($A$7="oui")*(1+$G$8*($A$8="oui"))))

La partie sur A8/G8, que ce soit oui ou non, rien ne bouge.

Vous pouvez m'aider ?

Merci

 

[Monique]

Re : Somme si..... Alors

Re,

Admettons un prix de base à 100
Après deux remises seulement, une remise de 20% et une autre de 10%,
tu veux quoi ? 70 ou 72 ?
Est-ce que la remise 2 s'applique sur le prix déjà réduit par la remise n° 1 ?

Si on continue comme tout à l'heure (j'ai mis 100 à la place de Recherchev :
=100*PRODUIT(1-$E$3:$E$6)*(1+SOMMEPROD(($A$7:$A$8="oui")*1;$G$7:$G$8))

(valider par ctrl, maj et entrée)

 

[isquiv94]

Re : Somme si..... Alors

Monique vous êtes un génie !

J'ai pas tout compris le pourquoi du comment, à la formule, mais le résultat est là, tous les calculs à base des formules marchent parfaitement.

Pour répondre à la première question, c'est effectivement des remises en cascades avec un résultat à 72.

Milles Mercis

Isquiv94