somme nombre de feuille variable

[Fred-R]

bonjour,

voici mon problème:

dans plusieures feuilles (Item (1), Item (2), etc.), je dois multiplier 2 cellules avant de les additionner dans ma feuille Projet.

j ai un nombre variable de feuille "Item" et plus de 60 lignes a compiler comme cela.

de plus, mon facteur est une case constante ex: $H$3

exemple de ce que j aimerais :

=SOMME('Item (1)'!B6*'Item (1)'!$H$1) mais qui est valide pour Item (1) à Item (x)

merci et bonne journée....

 

[wilfried_42]

Re : somme nombre de feuille variable

bonjour et bienvenue

je n'ai pas tout compris mais un essai avec indirect

[B]=sommeprod(indirect("'Item (1):Item (" & [B][COLOR="Red"]3[/COLOR][/B] & ")!B6");indirect("'Item (1):Item (" & [B][COLOR="red"]3[/COLOR][/B] & ")!H11"))[/B]

je ne suis pas sûr de la formule
en rouge, 3, j'ai mis en dur, mais ca peut etre la reference d'une cellule ou encore une formule donnant un n° de feuille

un fichier exemple serait le bienvenu

 

[BOISGONTIER]

Re : somme nombre de feuille variable

Bonsoir,

6 feuilles:

=SOMMEPROD((N(INDIRECT("'item ("&LIGNE(1:6)&")'!b6")))*N(INDIRECT("'item ("&LIGNE(1:6)&")'!H1")))


Le nombre de feuilles en A8

=SOMMEPROD((N(INDIRECT("'item ("&LIGNE(INDIRECT("1:"&A8))&")'!b6")))*N(INDIRECT("'item ("&LIGNE(INDIRECT("1:"&A8))&")'!H1")))

JB

 

[Fred-R]

Re : somme nombre de feuille variable

merci BOISGONTHIER...

maintenant j'aimerais savoir si c est possible, avec une formule, de lire le nombre de feuille Item pour ne pas avoir a rentre ce nombre manuellement.

merci

 

[Fred-R]

Re : somme nombre de feuille variable

voici mon tableau la formule doit etre bonne (ou s'adapter) pour les lignes 9 @ 88 de la feuille projet


j espere que ce sera plus claire ainsi

 

[wilfried_42]

Re : somme nombre de feuille variable

re:

pour connaitre le nombre de feuille qui contiennent item en formule il faut utiliser une Macro Excel 4 en formule nommée
Menu insertion/Noms/Définir
le nom : Feuille
la formule : =LIRE.CLASSEUR(1)
valider

la formule à placer dans une cellule :

=SOMMEPROD(ESTNUM(TROUVE("Item";Feuille))*1) + (maintenant()*0)

 

[Fred-R]

Re : somme nombre de feuille variable

re:

pour connaitre le nombre de feuille qui contiennent item en formule il faut utiliser une Macro Excel 4 en formule nommée
Menu insertion/Noms/Définir
le nom : Feuille
la formule : =LIRE.CLASSEUR(1)
valider

la formule à placer dans une cellule :

=SOMMEPROD(ESTNUM(TROUVE("Item";Feuille))*1) + (maintenant()*0)

Merci, je voulais savoir si vous seriez capable de l insérer dans le tableau que j ai posté car je ne m y connais pas dutout en macro ( ni en faire, ni ne éditer, ni savoir comment la faire fonctionner)

merci et bonne journée

 

[vbacrumble]

Re : somme nombre de feuille variable

Bonjour



Il suffit de suivre les indications données par Wilfried.

Aller dans le menu d'Excel Insertion puis choisir Noms

et là suivre le reste des indications précédentes.


PS: il ne s'agit pas de macro telle que celle utilisée en VBA

 

[Fred-R]

Re : somme nombre de feuille variable

j ai la version excel 2000 et je ne trouve pas comment entrer la formule

quelqu un peut me dire comment y acceder. j ai fait insertion, nom, définir et il m apparait seulement:

- nom dans le classeur: --> Feuille
- Fait référence à :--> ????

 

[vbacrumble]

Re : somme nombre de feuille variable

Re


Dans Fait référence à : tu saisis la formule
=LIRE.CLASSEUR(1)

puis tu cliques sur Ajouter, puis sur Fermer

 

[jeanpierre]

Re : somme nombre de feuille variable

Bonjour Fred-R, wilfried, vbacrumble,

Tu as toutes les indications dans le post de wilfried, reprécisé par vba crumble :

"et là suivre le reste des indications précédentes"

Donc, lorsque tu es dans le champ "Fait référence à", il te faut saisir la formule donnée plus haut puis Ajouter. Même si Excel sait avoir quelques automatismes, il ne sait pas encore deviner.

Bonne fin d'après-midi.

Jean-Pierre

 

[Fred-R]

Re : somme nombre de feuille variable

alors je viens de terminer mon Classeur.

Un gros merci a tous ceux qui m'ont aidé.

 

[BOISGONTIER]

Re : somme nombre de feuille variable

Bonsoir,

Autre solution sans cellule intermédiaire:

Créer un nom de champ NbFeuilles:=LIRE.CLASSEUR(4)

=SOMMEPROD((N(INDIRECT("'item ("&LIGNE(INDIRECT("1:"&NbFeuilles-1))&")'!b"&LIGNE()-3)))*N(INDIRECT("'item ("&LIGNE(INDIRECT("1:"&NbFeuilles-1))&")'!H1")))

JB