Somme(grande.valeur

[alex44510]

Bonjour,

J'ai cette formule:

=SOMME(GRANDE.VALEUR(PLAGE;{1;2;3;4;5;6;7;8;9;10}))

Je souhaiterais ajouter une condition a cette formule.

Je souhaiterai faire un TOP 10 avec une condition (la condition était sur un autre colonne que la PLAGE)

Est-il possible?

Cdt

 

[R@chid]

Re : Somme(grande.valeur

Bonjour,
Oui c'est possible, mais pas sans fichier exemple..
@ + +

 

[alex44510]

Re : Somme(grande.valeur

Voila avec un fichier Exemple

 

[R@chid]

Re : Somme(grande.valeur

Bonjour,

=SOMME(SIERREUR(GRANDE.VALEUR(SI(A2:A41="Janvier";B2:B41);LIGNE(1:10));))

@ valider par Ctrl+Maj+Entree

La SIERREUR() ici est juste si on n'a pas 10 valeurs sur janvier...

@ + +

 

[alex44510]

Re : Somme(grande.valeur

Merci pour ton aide.

Voila mon Exemple concret qui est un petit plus complexe.

Cdt,

Alex

 

[R@chid]

Re : Somme(grande.valeur

Re,
Ton fichier n'est pas passé

 

[alex44510]

Re : Somme(grande.valeur

Sorry

Alex

 

[Misange]

Re : Somme(grande.valeur

Bonjour

avec les données sous forme de Ce lien n'existe plus et en utlisant la fonction Ce lien n'existe plus, ce qui est utile si il y a des valeurs d'erreur, des valeurs filtrées ou des valeurs masquées dans la liste qu'il faut gérer :
=SOMME(AGREGAT(14;6;SI(Tableau1[MOIS]="Janvier";Tableau1[VENTES]);LIGNE(1:10)))
Fonction matricielle à valider par ctrl+maj+entrée

 

[R@chid]

Re : Somme(grande.valeur

Re,
Salut Misange,

=SOMME(GRANDE.VALEUR(SI((B3:B16192="BU_BRICOLAGE")*(D3:D16192=1);E3:E16192);LIGNE(1:10)))

@ valider par Ctrl+Maj+Entree
@ + +

 

[alex44510]

Re : Somme(grande.valeur

Merci beaucoup R@chid , c'est exactement ce qu'il me fallait
@Misange: Merci à toi aussi

A+

 

[R@chid]

Re : Somme(grande.valeur

Re,
Tu peux utiliser la formule de Misange,

=SOMME(AGREGAT(14;6;SI((B3:B16192="BU_BRICOLAGE")*(D3:D16192=1);E3:E16192);LIGNE(1:10)))

elle est belle aussi
@ + +

 

[Misange]

Re : Somme(grande.valeur

Hello

ou bien encore
=SOMME(GRANDE.VALEUR((Tableau1[BU]="BU_BRICOLAGE")*(Tableau1[Mois]=1)*(Tableau1[Comm avec FdP]);LIGNE(1:10)))
(pas besoin du si)
ou encore
=SOMME(AGREGAT(14;6;(Tableau1[BU]="BU_BRICOLAGE")*(Tableau1[Mois]=1)*(Tableau1[Comm avec FdP]);LIGNE(1:10)))

tout ça en matricielle bien sur
Toujours préférer avec excel 2007 et + le fait de travailler avec des tableaux excel. Ca rend les choses dynamiques (pas besoin de modifier tes formules si tu ajoutes des valeurs, ni de définier des noms avec la fonction decaler), ça rend les formules plus faciles à suivre et surtout ça évite de devoir aller se balader avec la souris jusqu'en bas du tableau pour saisir les références des plages.