Somme décaler

[CAMPEN]

Bonjour le Forum,

J'ai un petit os sur un tableau qui doit être simple à résoudre :
je souhaite faire une somme variable en fonction d'un critère. Dans mon exemple, je souhaite faire la somme de janvier au mois indiqué en B6 : par exemple, si mars alors somme de janvier à mars. Je joins le fichier.
Merci par avance de votre aide

 

[Raja]

Re : Somme décaler

Bonjour,

Essaye la formule suivante :

=SOMME(B2:DECALER(B2;;EQUIV(B6;B1:M1;0)-1))

 

[CAMPEN]

Re : Somme décaler

Super !
Merci Raja , c'est ça ce qu'il me fallait...

 

[abcd]

Re : Somme décaler

Bonjour, salut raja,

Variante : =SOMME(B2: DECALER(A2;;MOIS(1&B6)))

abcd

 

[Raja]

Re : Somme décaler

Re, Salut abcd,

Formule inpirée de l'idée proposée par abcd :

=SOMMEPROD((MOIS(1&B1:M1)<=MOIS(1&B6))*(B2:M2))

 

[TheProdigy]

Re : Somme décaler

Pourquoi MOIS(1&B6) en non pas MOIS(B6)?
Merci

 

[abcd]

Re : Somme décaler

Bonjour (c'est plus poli),

As-tu essayé et quel est le résultat ?

abcd

 

[gerson94]

Re : Somme décaler

Bonjour (c'est plus poli),

As-tu essayé et quel est le résultat ?

abcd

Bonjour tout le monde,

Cette solution m'intéresse, Campen comme le dit abcd peux-tu partager ton fichier avec l'une des solutions à l'intérieur

Merci et bonne fin de journée à tous

gerson

 

[TheProdigy]

Re : Somme décaler

Bonosoir,(Je suis poli)

J'ai déjà essayé mais cela donne Erreur

Merci

 

[abcd]

Re : Somme décaler

Re,

C'est bien ce qui me semblait aussi !

Comme tu ne précises pas à quelle formule tu fais référence, je te réponds pour les deux :

DECALER(A2;;MOIS(1&B6))
le 3ème argument doit préciser le nombre de colonnes à décaler.
MARS n'est pas un nombre tandis que MOIS(1&"mars") ou MOIS(1&B6) renvoient 3, une valeur numérique.

MOIS(1&B1:M1)<=MOIS(1&B6) compare des valeurs numériques
MOIS(B1:M1)<=MOIS(B6) compare des valeurs alphabétiques.
or : ="mars"<"avril" renvoie FAUX, parce qu'Excel compare les caractères un à un à partir de la gauche et que "m" est > "a".
Si les mois étaient triés alphabétiquement, on pourrait employer la 2ème formule, mais ce n'est pas le cas.

J'espère avoir répondu à ta question.

abcd

 

[Gael]

Re : Somme décaler

Bonsoir à tous,

A partir de la formule de Abcd (merci pour l'astuce du 1&B6 que je ne connaissais pas):

=SOMME(DECALER($B$2;;;;MOIS(1&$B$6)))

@+

Gael

 

[TheProdigy]

Re : Somme décaler

Merci parfaite explication.

 

[TheProdigy]

Re : Somme décaler

Bonsoir tout le monde
Pourquoi dans mon fichier la formule marche sans 1&

=SOMME(DECALER(B2;;;;MOIS(A5)))

Merci

 

[Gael]

Re : Somme décaler

Re,

Tout simplement parceque A5 contient une date qui affichée au format "mmm", mais c'est une valeur numérique dont Excel peut extraire le mois.

Dans les fichiers précédents "Mars" était écrit sous forme de texte.

@+

Gael

 

[TheProdigy]

Re : Somme décaler

Merci bien