Somme de temps

[ajulien]

Bonjour a tous !
J'ai quelques notions dans excel mais la je dois dire que je cale !
En effet, je souhaite additionner les temps de mes nageurs dans excel.
Je rentre mes temps au format 00'00''00 mais apres pour les additionner ca me donne des 90''00 au lieu de 1'00''00 ou des 2'60''00 au lieu de 3'00''00.
En d'autres termes je veux additionner des minutes secondes centiemes et si possible les entrer au format 00'00''00 (que j'ai juste a rentrer 12548 pour 1'25''48 !)
Si vous pouviez m'aider ca serait génial ^^
Merci d'avance et a bientot 😉

 

[Baside]

Re : Somme de temps

Bonsoir le Forum,

Avec un petit extrait de ton fichier, ce serait plus simple, il me semble.

Amicalement, Hervé.

 

[Catrice]

Re : Somme de temps

Bonsoir,

Voir un exemple dans le fichier joint.

 

[Monique]

Re : Somme de temps

Bonjour,

SommeProd pour faire la somme des temps
Format horaire pour la somme : [m]"min "ss,00 ou bien [mm]"min "ss,00

=SOMMEPROD(ENT(B3:B11/10000)/1440+MOD(ENT(B3:B11/100);100)/86400+MOD(B3:B11;100)/8640000)

 

[Catrice]

Re : Somme de temps

Bonjour Monique, Bonjour Ajulien,

Pour un calcul de somme dans une cellule (sans colonne intermediaire) il y a aussi :
=SOMMEPROD(TEMPSVAL(TEXTE(A4:A11;"0\:00\.00")))

Voir fichier joint.

Eventuellement remplacer la formule par :
=SOMMEPROD(TEMPSVAL(TEXTE(A4:A11;"0\:00\,00")))

Suivant le séparateur décimal utilisé.

 

[Catrice]

Re : Somme de temps

Re,

Une version qui fonctionne quel que soit le séparateur décimal (point ou virgule).
=SOMMEPROD(TEMPSVAL(TEXTE(A4:A11;"0\:00\"&SI(ESTNUM("1.1"*1);".";",")&"00")))

Voir fichier joint.

 

[ajulien]

Re : Somme de temps

Merci beaucoup ! ca fonctionne super bien j'ai modifié la disposition pour que ca soit plus simple pour moi. En tout cas reponse claire, precise et en meme temps demarche de calcul super bien expliquee. Chapeau a vous et encore merci
@ bientot ^^😀

 

[Monique]

Re : Somme de temps

Bonjour,

C'est vrai, en plus, Catrice
Celle-ci est plus courte (*1 ou /1 ou +0 ou -0 à la place de Dateval) :

=SOMMEPROD(TEXTE(B4:B11;"0\:00\"&SI(ESTNUM("1.1"*1);".";",")&"00")*1)

 

[Catrice]

Re : Somme de temps

Merci Monique,

J'ai tendance à etre un trop académique 😉