Simplifer une formule

[Lipadec]

Bonsoir le Forum

Vous voudrez bien m'aider à simplifier cette formule que je trouve un peu longue

=SI($B$10<>"";(INDEX(BASE!$A:$FB;EQUIV($A$10&$H$8&$J$8;BASE!$B:$B;0);58)+INDEX(BASE!$A:$FB;EQUIV($A$10&$H$8&$J$8;BASE!$B:$B;0);59)+INDEX(BASE!$A:$FB;EQUIV($A$10&$H$8&$J$8;BASE!$B:$B;0);60)+INDEX(BASE!$A:$FB;EQUIV($A$10&$H$8&$J$8;BASE!$B:$B;0);61)+INDEX(BASE!$A:$FB;EQUIV($A$10&$H$8&$J$8;BASE!$B:$B;0);62));"")

J"ai essayé tout seul, mais je ne suis pas arrivé à la simplifier.

Merci pour votre aide

Lipadec

 

[Dranreb]

Re : Simplifer une formule

Bonsoir.
Ceci ne serait-il pas bon ?:

=SI($B$10<>"";SOMME(INDEX(BASE!$BF:$BJ;EQUIV($A$10&$H$8& $J$8;BASE!$B:$B;0)));"")

À +

 

[Lipadec]

Re : Simplifer une formule

Re

Merci Dranreb pour ta réponse, mais ça ne fonctionne pas, quand j'ai mis ta formule à la place de la mienne, elle me donne #REF!

Je cherche autre chose

A +

 

[Dranreb]

Re : Simplifer une formule

Eh bien mettez la au point, je ne peux pas moi, puisque vous n'avez pas joint de fichier. Normalement elle devrait marcher si votre EQUIV que vous aviez mis 5 fois marche: je l'ai repris tel que vous l'aviez écrit !
Essaye de le remplacer par 10 pour voir si ça prends bien les valeur de la 10ième ligne par exemple:

=SOMME(INDEX(BASE!$BF:$BJ;10;0))

Ah ! Il manquait 0. Enfin comme dit je n'ai pas pu tester jusqu'à ce que ce soit bon.

=SI($B$10<>"";SOMME(INDEX(BASE!$BF:$BJ;EQUIV($A$10&$H$8& $J$8;BASE!$B:$B;0);0));"")

C'est la dernière fois que j'examine une demande sans pièce jointe. Mais ça doit bien faire cent fois que je me dit ça, et une ou deux fois par mois j'entre quand même accidentellement dans l'une d'elles...

 

[Lipadec]

Re : Simplifer une formule

Bonjour le Forum et grand merci pour toi Dranreb
Cette fois, ta formule marche très bien, je viens de l'essayer
Quant au fichier dont tu parles, c'est un grand classeur Excel de plus de 15 Mo que je ne pouvais pas envoyer même zippé.
En tout cas je te remercie et merci pour le forum qui nous donne l'occasion de communiquer malgré la distance qui nous sépare
Bonne fin de journée

Lipadec