Si trouve je n'y arrive pas

[sendlyne1]

JE SOUHAITE TROUVER PLUSIEURS CONDITIONS .MA FORMULE NE FONCTIONNE PAS MERCI
SI(TROUVE("GIS";C4);"malle ordi";"";("Grue";C4);"GRUE";"")

 

[Victor21]

Re : Si trouve je n'y arrive pas

Bonsoir à vous également 😡 sendlyne1.

Ecrivez moins FORT, s'il vous plait. On n'est pas aveugles.

 

[xhudi69]

Re : Si trouve je n'y arrive pas

Bonsoir sendlyne1, le Forum
Bonsoir Victor21 🙂

Peut-être ceci.........

=SI(C4="GIS";"malle ordi";SI(C4="GRUE";"GRUE";""))

@😎

 

[sendlyne1]

Re : Si trouve je n'y arrive pas

Merci xhudi69 avec un peut de retard.
J'ai essayé de l 'adapter car cela ne fonctionne qu'avec le premier mot trouver et marque dans toutes la colonne "GIS"

 

[Staple1600]

Re : Si trouve je n'y arrive pas

Bonjour à tous

En minuscule, BONJOUR s'écrit b o n j o u r
sendlyne1, repète aprés moi:
b
o
n
j
o
u
r

Etre pressé n’empêche pas d'être poli, non ?

PS: Si tu demandes de l'aide, il serait peut-être utile (à défaut d'être courtois) de suivre les conseils qu'on te donne.
En effet dans plusieurs de tes discussions, plusieurs membres te conseillent de joindre un fichier exemple.
Pourquoi ne le fais-tu pas dans celle-ci?

 

[sendlyne1]

Re : Si trouve je n'y arrive pas

veuillez m'excuser ,bonjour à tous et merci pour votre aide.J'ai déja trouvé beaucoup de réponses et formules intérressantes dans ce forum,que j'ai pu adapter à mes besoins,ci joint un fichier pour ma demande actuelle

 

[Staple1600]

Re : Si trouve je n'y arrive pas

Re

Je me suis égaré dans la futile complexité par désœuvrement dominical mais cela fonctionne 😉

=CHOISIR(EQUIV(CHERCHE("VRAI";T(ESTNUM(CHERCHE("gis";B11))&(ESTNUM(CHERCHE("grue";B11))&ESTNUM(CHERCHE("tp";B11)))));{1;5;9});"malette ordi";"louer grue aux";"louer engin")

Vite appelez l'exorciste 😉... ou un formuliste émérite d'XLD derechef.

 

[Victor21]

Re : Si trouve je n'y arrive pas

Bonjour, sendlyne, JM 🙂

Une autre ? bon, OK : Essayez :

=SI(ESTNUM(TROUVE("gis";B3));"malette ordi";"")&SI(ESTNUM(TROUVE("grue";B3));"louer grue aux";"")&SI(ESTNUM(TROUVE("tp";B3));"louer engin";"")

 

[sendlyne1]

Re : Si trouve je n'y arrive pas

Merci beaucoup,les 2 fonctionnes.

 

[job75]

Re : Si trouve je n'y arrive pas

Bonjour à tous,

S'il ne peut y avoir qu'un seul des 3 textes :

=REPT("malette ordi";NB.SI(B3;"*gis*"))&REPT("louer grue aux";NB.SI(B3;"*grue*"))&REPT("louer engin";NB.SI(B3;"*tp*"))

Sinon en les séparant par un espace :

=SUPPRESPACE(REPT("malette ordi ";NB.SI(B3;"*gis*"))&REPT("louer grue aux ";NB.SI(B3;"*grue*"))&REPT("louer engin";NB.SI(B3;"*tp*")))

A+

 

[Staple1600]

Re : Si trouve je n'y arrive pas

Re, bonjour job75


Histoire de s'occuper ou pour le fun

=INDEX({"malette ordi";"louer grue aux";"louer engin"};SOMMEPROD(ESTNUM(CHERCHE({"gis";"grue";"tp"};B11))*LIGNE($1:$3)))

Je la trouve plus jolie que ma première formule, c'est déjà ça 😉

 

[job75]

Re : Si trouve je n'y arrive pas

Re,

Toujours histoire de s'occuper, comparaison des "poids" des formules :

- formule du post #7 => 188 octets

- formule du post #8 => 159 octets

- formule du post #10 (1) => 105 octets

- formule du post #10 (2) => 110 octets

- formule du post #11 => 126 octets

A+

 

[job75]

Re : Si trouve je n'y arrive pas

Re,

Cela dit la dernière formule de Staple1600 est intéressante, surtout utilisée avec des plages de cellules :

=INDEX(I$11:I$13;SOMMEPROD(ESTNUM(CHERCHE(H$11:H$13;B11))*LIGNE($1:$3)))

Elle ne "pèse" alors que 51 octets.

Voir fichier joint.

Nota : sur Excel 2007 et versions suivantes, pour éviter les valeurs d'erreur :

=SIERREUR(INDEX(I$11:I$13;SOMMEPROD(ESTNUM(CHERCHE(H$11:H$13;B11))*LIGNE($1:$3)));"")

A+

 

[job75]

Re : Si trouve je n'y arrive pas

Re,

Bon la formule de Staple1600 ne va pas si l'on déplace la plage H11:I13 en H14:I16...

Il faut la mettre en dehors des lignes traitées.

A+

 

[job75]

Re : Si trouve je n'y arrive pas

Bonjour le fil, le forum,

Je complète mon post #14.

=INDEX(I$14:I$16;xxx) ne va pas si xxx = 0, alors écrire =INDEX(I$14:I$16;EXP(LN(xxx))) :

=INDEX(I$14:I$16;EXP(LN(SOMMEPROD(ESTNUM(CHERCHE(H$14:H$16;B11))*LIGNE($1:$3)))))

Fichier (2).

Nota : on peut aussi écrire 1/(1/(xxx)) mais ça prend 10 octets alors que EXP(LN(xxx)) prend 6 octets...

A+