SI et OU

[jad73]

bonjour
comment formuler SI avec plusieurs OU
Ex:SI(A1=1ou2ou3ou4;alors 0)
j'ai éssayé si(a1=1,2,3,4;0) ,si(a1="1,2,3,4";0) ,si(a1="1""2""3""4";0)
cela ne fonctionne pas.
merci

 

[vbacrumble]

Re : SI et OU

Bonsoir

=SI(OU(A1=1;A1=2;A1=3;A1=4);0;"")

ou deux autres possibilités (sans utiliser la formule SI )

=NON(((A1=1)+(A1=2)+(A1=3)+(A1=4)))*1

=ESTERREUR(CHOISIR(A1;0;0;0;0))*1

 

[lematou]

Re : SI et OU

Bonjour, voici le résultat
Bonne soirée

 

[jad73]

Re : SI et OU

bjr vbacrumble
jai oublié de préciser que j'avais déja 5 SI dans la formule
la voici =SI(X3=0;2;SI(X3=5;2;SI(X3=6;20;SI(X3=7;100;SI(X3=8;120)))))
je voudrais rajouter SI(X3=1 ou 2 ou3 ou 4 ;0) comme il ne faut que 7 arguments alors ça fait trop long.
merci

 

[vbacrumble]

Re : SI et OU

Re



Est-ce que tu as compris la syntaxe de OU utilisée avec SI ?

Voir la formule dans le précédent message.

 

[Tibo]

Re : SI et OU

Bonjour,

La fonction CHOISIR devrait répondre à ta demande :

=CHOISIR(X3;réponse1;réponse2;réponse;......réponse10)

Tu as la possibilité de mettre 30 arguments dans cette fonction.

Je te laisse essayer.

Si pas ça, reviens avec plus de détails (un fichier commenté par exemple)


@+

 

[abcd]

Re : SI et OU

Bonjour,

Essaie ceci :

=(X3=5)*2+(X3=6)*20+(X3=7)*100+(X3=8)*120
Toutes les autres valeurs de X3 → <5 et >8 renvoient 0
Plus de limite dans le nombre de conditions.

Il y a aussi moyen de le faire par un RECHERCHEV avec toutes les conditions dans la formule.
=SI(OU(X3<5;X3>8);0;RECHERCHEV(X3;{5\2;6\20;7\100;8\120};2))

abcd

 

[jad73]

Re : SI et OU

bjr
merci a tous,j'ai mis la 1ere formule d'abcd,n'etant pas trés doué en formule elle etait la plus facile a écrire
merci

 

[nolich]

Re : SI et OU

Bonjour jad73, vbacrumble, lematouTibo et abcd, bonjour à toutes et à tous 🙂

jai oublié de préciser que j'avais déja 5 SI dans la formule
la voici =SI(X3=0;2;SI(X3=5;2;SI(X3=6;20;SI(X3=7;100;SI(X3=8;120)))))
je voudrais rajouter SI(X3=1 ou 2 ou3 ou 4 ;0) comme il ne faut que 7 arguments alors ça fait trop long.

Je vois que tu as =SI(X3=0;2;... Il faut donc un peu modifier la formule que t'as donnée abcd.

Essaie ceci :

=(X3=5)*2+(X3=6)*20+(X3=7)*100+(X3=8)*120
Toutes les autres valeurs de X3 → <5 et >8 renvoient 0

Et je pense qu'abcd ne m'en voudras pas de la compléter comme suit :

=(X3=0)*2+(X3=5)*2+(X3=6)*20+(X3=7)*100+(X3=8)*120

@+

 

[abcd]

Re : SI et OU

Salut nolich,

Bien merci pour la correction, j'avais oublié cette condition.

Mais que penses-tu de :
=OU(X3=0;X3=5)*2+(X3=6)*20+(X3=7)*100+(X3=8)*120

abcd