Report dans cellule

[patgravure35]

Bonjours a tous et toutes

Voilà un autre problème

Je cherche à recopier des N° de CMD dans des cellules

Rien de bien compliqué sauf que je veux recopier que les 6 premiers chiffres de ses n°
Inscrit dans une colonne et les recopier qu’une seul fois si ils sont en double

Je vous joint un petit model

Merci d’avance et à bientôt

 

[Robert]

Re : Report dans cellule

Bonsoir Patgravure, bonsoir le forum,

Peut-ête comme ça :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl
Dim dico As Object 'déclare la variable dico (DICtiOnnaire)
Dim pl As Range 'déclare la variable pl (PLage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim temp As Variant 'déclare la variable temp
Dim i As Integer 'décalre la variable i (Incrément)

Set dico = CreateObject("Scripting.Dictionary") 'définit le dictionnaire dico
With Sheets("Feuil1") 'prend en compte l'onglet "Feuil1"
    dl = .Cells(Application.Rows.Count, 6).End(xlUp).Row 'définit la dernière ligne éditée de la colonne F dl
    Set pl = .Range("F2:F" & dl) 'définit la plage pl
    For Each cel In pl 'boucle sur toutes les celllules cel de la plage pl
        dico(Left(cel.Value, 6)) = "" 'alimente le dictionnaire avec les 6 premiers caractères de chaque cellule
    Next cel 'prochaine cellule de la boucle
    temp = dico.keys 'récupère les valeurs du dictionnaire sans doublon
    For i = 0 To UBound(temp) 'boucle sur toutes les valeurs sans doublons
        .Cells(7 + i, 15).Value = temp(i) 'place la valeur dans la colonne O à partor de la ligne 7
    Next i 'prochaine valeur de la boucle
End With 'fin de la prise en compte de l'onglet "Feuil1"
End Sub

 

[patgravure35]

Re : Report dans cellule

merci beaucoup robert pour ton aide presieuse

pourrais tu me dire comment execcuter cet macro automatiquement

et merci encor pour tout

a bientôt

 

[Robert]

Re : Report dans cellule

Bonjour Patgravure, bonjour le forum,

Tu rajoutes un bouton et tu lui affectes la macro que je t'ai porposé...
Ton fichier modifié :