XL 2019 Répartition d'un montant entre deux dates

[Charles2133]

Bonjour à tous,

J'aimerais répartir le montant total d'un contrat (dans le fichier 10K) sur les mois du contrats (dans les colonnes E à P) en fonction de la date de début et de fin de ce contrat (colonne B et C) et j'arrive pas à trouver la bonne formule !!!

Merci bcp de votre aide!

 

[Hasco]

Bonjour,

Dans le fichier joint, la formule

=(FIN.MOIS($B2;0)<=E$1)*(FIN.MOIS($C2;0)>=E$1)
*($D2/($C2-$B2+1))*(JOUR(E$1)
+(1-JOUR($B2))*(FIN.MOIS($B2;0)=E$1)
+(JOUR($C2)-JOUR(E$1))*(FIN.MOIS($C2;0)=E$1))

En fin de ligne une cellule qui somme la décomposition pour vérification
Cordialement

 

[Victor21]

Bonjour @Charles2133 , Roblochon 🙂.

Essayez en E2 :
=$D2/($C2-$B2)*MAX(0;MIN(E$1;$C2)-$B2)-SOMME($D2: D2)+$D2

 

[Hasco]

Bonjour,

Dans le fichier joint,
La formule de @Victor21 que je trouve superbe ( la formule pas Victor, quoique sous certains angle???)
Et un nouvelle formule, que je pourrai plus facilement reproduire ultérieurement : =$D2/($C2-$B2)*(MEDIANE($C2;E$1;FIN.MOIS(E$1;-1))-MEDIANE($B2;E$1;FIN.MOIS(E$1;-1)))

Deux approches différentes mais toutes aussi utiles me semble-t-il. Une par cumul et réduction, l'autre par 'tranchage'.

Peut-être que quelqu'un aura d'autre(s) proposition(s) à rassembler dans le classeur.

Bon week-end