Renvoi Feuille Excel sur Access

[Erebus75]

Bonjour le forum,

Je voudrais renvoyer un feuille Excel sur Access, je pensais qu'en faisant un simple copier/coller de l'un sur l'autre fonctionnerait mai apparament non, j'ai réussit de Access sur Excel mais l'inverse ne fonctionne pas.

Y a t il un moyen?

Merci

 

[RENAUDER]

Re : Renvoi Feuille Excel sur Access

Bonjour,

Dans Access tu peux importer des données d'Excel.
Sinon ce code doit faire l'affaire (je ne l'ai pas retesté)
Ne pas oublier d'ajouter la référence Microsoft ActiveX Data Objects 2.7 ou 2.8

Sub ADOFromExcelToAccess()
' exports data from the active worksheet to a table in an Access database
' this procedure must be edited before use
Dim cn As ADODB.Connection, rs As ADODB.Recordset, r As Long
    ' connect to the Access database
    Set cn = New ADODB.Connection
    cn.Open "Provider=Microsoft.Jet.OLEDB.4.0; Data Source=C:\FolderName\DataBaseName.mdb;"
    ' open a recordset
    Set rs = New ADODB.Recordset
    rs.Open "TableName", cn, adOpenKeyset, adLockOptimistic, adCmdTable  ' all records in a table
    r = 3 ' the start row in the worksheet
    Do While Len(Range("A" & r).Formula) > 0 ' repeat until first empty cell in column A
        With rs
            .AddNew ' create a new record
            ' add values to each field in the record
            .Fields("FieldName1") = Range("A" & r).Value
            .Fields("FieldName2") = Range("B" & r).Value
            .Fields("FieldNameN") = Range("C" & r).Value
            ' add more fields if necessary...
            .Update ' stores the new record
        End With
        r = r + 1 ' next row
    Loop
    rs.Close
    Set rs = Nothing
    cn.Close
    Set cn = Nothing
End Sub

 

[Erebus75]

Re : Renvoi Feuille Excel sur Access

Bonjour Renauder,

Merci, j'avais oublié comment faire (je n'utilise que très rarement Access), j'ai réussi le transfert des données. malgrès tout, j'essayerais quand même la macro que tu m'as donné.

Encore une fois merci beaucoup