XL 2016 Regrouper plusieurs lignes sur une seule en fonction d'un code

[tpl]

Bonjour tout le monde
Je sollicite votre aide pour le traitement suivant (j'ai déjà perdu des heures à travailler manuellement !!)
* j'ai une liste d'articles avec un code et un montant
* parfois ces articles se répètent mais avec d'autres montants
* comment les sommer et regrouper que sur seule ligne ?
J'ai détaillé dans le fichier joint
Merci d'avance pour votre aide
PS : ne connaissant rien à la macro (si, si..) j'aurais souhaité une solution par fonction

 

[chris]

Bonjour

En E5 à étirer en-dessous

=SI(A5<>A6;SOMME.SI.ENS($D$5:D5;$A$5:A5;A5);0)

Plus formatage nombre de la colonne
# ##0,00_ ;[Rouge]-# ##0,00\ ;

 

[R@chid]

Bonsoir,
ce n'est pas clair,
en E5 :

=SI(NB.SI(A$5:A5;A5)=NB.SI(A$5:A$516;A5);SOMME.SI(A$5:A$516;A5;D$5:D$516);"")

@ tirer vers le bas


Cordialement

Edit : Salut Chris

 

[chris]

RE à tous

La formule de r@chid est plus juste si on retouve le même code à plusieurs endroits

 

[tpl]

Génial ! Merci beaucoup pour votre aide
Pour la suite, j'ai un autre problème
J'ai donc mis la formule et çà fonctionne impeccable (onglet "avec formule")
Après j'utilise ces résultats pour les amener dans un autre fichier. Or ici l'article ne figure qu'une fois alors que de l'autre côté il est sur plusieurs lignes
Du coup la recherche = vide (cf onglet "nouv prob") ==> lignes en rose
Merci encore pour votre aide

 

[R@chid]

Bonsoir,
en B2 :

=SIERREUR(INDEX('avec formule'!E$5:E$516;EQUIV(A2;'avec formule'!A$5:A$516;0)+NB.SI('avec formule'!E$5:E$516;A2)-1);"")

@ tirer vers le bas

La fonction RECHERCHEV() ne renvoie que la première valeur trouvée, alors que s'il des doublons, le montant apparait avec la dernière occurrence.

Cordialement

 

[JHA]

Bonjour à tous,

Je pense qu'il y a une petite modification à faire sur la formule de @rachid 😉
"NB.SI('avec formule'!E$5:E$516;A3)" mettre "A$5:A$516"

Autrement il y a aussi

=SOMMEPROD(('avec formule'!$E$5:$E$516<>"")*('avec formule'!$A$5:$A$516='nouv prob'!$M2);('avec formule'!$E$5:$E$516))

Attention, les doubles dans la colonne "A" affectent le résultat en "B1"

JHA

 

[tpl]

Bonjour !
Encore une fois merci à tous (chris, rachid JHA, ..) pour votre aide toujours efficace et rapide
Bon WE !!

 

[R@chid]

Bonjour @ tous,
Salut JHA,

Je pense qu'il y a une petite modification à faire sur la formule de @rachid 😉
"NB.SI('avec formule'!E$5:E$516;A3)" mettre "A$5:A$516"

Merci de me l'avoir signalé, j'ai pas fait attention à cette grave erreur.

Merci

=SIERREUR(INDEX('avec formule'!E$5:E$516;EQUIV(A2;'avec formule'!A$5:A$516;0)+NB.SI('avec formule'!A$5:A$516;A2)-1);"")

Sinon, SOMMEPROD() comme la tienne ou bien SOMME.SI() feront l'affaire si jamais les données ne sont pas triées.


Cordialement