Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° ligne

[Merlin258413]

Bonjour j'ai le tableau de synthèse ci joint qui compte le nombre de matricule en colonne A sans doublons et avec pour critère le code BU.

J'utilise la formule ci-dessous qui fonctionne bien.

=SOMMEPROD((1/NB.SI('Livre de paie'!$A$5:$A$210;'Livre de paie'!$A$5:$A$210)*('Livre de paie'!$B$5:$B$210=SYNTHESE!A8)*(('Livre de paie'!$D$5:$D$210="DIRECT"))))

J'édite cet état tous les mois donc chaque mois donc je peux avoir des variations d'effectifs.
hors je suis bloqué sur le nombre de ligne ici 210 que je veux rendre variable.

Je pensais passer par indirect est utilisée la cellule A1 qui me donne le numéro de la dernière ligne de la colonne A livre de paie. mais je n'y arrive pas car j'ai une erreur

Pouvez vous m'aider svp ? Excellente journée

 

[ERIC S]

Re : Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° l

Bonjour

non testé mais regarde pour remplacer
'Livre de paie'!$A$5:$A$210 par DECALER('Livre de paie'!$A$5;0;0;nbval('Livre de paie'!$A:$A);1)

ià adapter pour B et D

 

[JCGL]

Re : Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° l

Bonjour à tous,

Peux-tu essayer avec :

=SOMMEPROD((1/NB.SI(INDIRECT("'Livre de paie'!$A$5:$A$"&$A$1);INDIRECT("'Livre de paie'!$A$5:$A$"&$A$1))*(INDIRECT("'Livre de paie'!$B$5:$B$"&$A$1)=SYNTHESE!A4)*((INDIRECT("'Livre de paie'!$D$5:$D$"&$A$1)="DIRECT"))))

A+ à tous

 

[Merlin258413]

Re : Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° l

Bonjour je vous remercie pour vos réponses rapides
ERIC S avec la fonction décaler j'ai une erreur de type DIV
JCGL cela fonctionne parfaitement
encore merci

 

[ERIC S]

Re : Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° l

Re

pour le fun et pour les éventuels spéléologues futurs

=SOMMEPROD(1/NB.SI(DECALER('Livre de paie'!$A$5;0;0;NBVAL('Livre de paie'!A:A)-1;1);DECALER('Livre de paie'!$A$5;0;0;NBVAL('Livre de paie'!A:A)-1;1))*(DECALER('Livre de paie'!$B$5;0;0;NBVAL('Livre de paie'!A:A)-1;1)=SYNTHESE!A4)*(DECALER('Livre de paie'!$D$5;0;0;NBVAL('Livre de paie'!A:A)-1;1)="DIRECT"))

doit marcher sans erreur, et sans avoir besoin de A1

 

[Merlin258413]

Re : Compter le nombre de valeurs sans doublons d'une colonne et rendre variable n° l

merci beaucoup cela fonctionne aussi. parfait
Bonne soirée à tous