XL 2010 Récupérer les adresses de 2 cellules fusionnées

[Magic_Doctor]

Bonsoir,

J'ai 2 cellules fusionnées (H5 & H6) que j'ai nommées "ZAZA".
Je voudrais récupérer leur adresse à partir de "ZAZA".
Si j'écris :

[E14] = [ZAZA].Address

j'obtiendrai en E14 : $H$5 (la 1ère cellule).
Comment s'y prendre pour pouvoir récupérer $H$6 ?

 

[Staple1600]

Bonsoir

Comme ceci
Sub test()
MsgBox [ZAZA].Item(2).Address
End Sub

 

[Staple1600]

Re

Ou plus complet

Sub test_II()
Dim Fuz
Fuz = Split([ZAZA].MergeArea.Address(0, 0), ":"): [E4] = Fuz(0): [E5] = Fuz(1)
End Sub

 

[mapomme]

Bonsoir @Magic_Doctor ,

Essayez :

Sub test()
   MsgBox Range("zaza").MergeArea(1).Address
   MsgBox Range("zaza").MergeArea(2).Address
End Sub

 

[Staple1600]

Bonjour mapomme

Tu n'aimes pas le Banana Split ?
(cf message#3)
Ni l'Item?
(cf message#2)

 

[job75]

Bonsoir Magic_Doctor, JM, mapomme,

D'après ce que je comprends il suffit de :

MsgBox [ZAZA].MergeArea.Address(0, 0)

Bonne nuit.

 

[Staple1600]

Bonsoir job75

Comment s'y prendre pour pouvoir récupérer $H$6 ?

J'ai compris qu'il voulait scinder
D'où le Split

Et si il faut les $, alors

Sub test_III()
Dim Fuz
Fuz = Split([ZAZA].MergeArea.Address, ":"): [E4] = Fuz(0): [E5] = Fuz(1)
End Sub

 

[Magic_Doctor]

Bonsoir à tous,

Merci pour vos réponses.
En attendant de vous lire, j'avais bidouillé un truc lourd, très lourd, mais qui marche :

Sub MesAdresses()

    Dim adresse1$, adresse2$, fila&
 
    adresse1 = [ZAZA].Address
    fila = Split(adresse1, "$")(2) + 1
    adresse2 = "$" & Split(adresse1, "$")(1) & "$" & fila
 
    [A1] = adresse1
    [A2] = adresse2
 
End Sub

Je résumerai donc ainsi :

Sub MesAdresses()

    Dim adresse1$, adresse2$
 
    adresse1 = [ZAZA].Address          'adresse de la 1ère cellule qui constitue la plage nommée "ZAZA"
    adresse2 = [ZAZA].Item(2).Address  'adresse de la 2ème cellule qui constitue la plage nommée "ZAZA"
 
    [A1] = adresse1
    [A2] = adresse2
 
End Sub

Merci encore pour votre aide.
Bonne fin de soirée.

 

[Staple1600]

Re

Voici le résumé de ton résumé

Sub MesAdresses()
[A1:A2] = Application.Transpose(Split([ZAZA].MergeArea.Address, ":"))
End Sub

 

[Staple1600]

Re

Et une dernière pour la route

Sub RésuméDuRésuméDuRésumé()
With [ZAZA]: [A1] = .Item(1).Address: [A2] = .Item(2).Address: End With
End Sub

 

[Magic_Doctor]

Bonjour Staple1600,

J'aime bien la dernière.

 

[laurent950]

Bonsoir le Forum

Sub test()
' 5 cellules fusionnées (H5 & L6) que j'ai nommées "ZAZA".
Dim TabAdress() As Variant
Dim Rgn As Range
Dim i As Range
Dim cpt As Byte: cpt = 1
    Set Rgn = Range("ZAZA")
        If Rgn.MergeCells = True Then
            MsgBox "Il y a " & Rgn.MergeArea.Count & " Cellules Fusionnées"
            ReDim TabAdress(1 To cpt)
            For Each i In Rgn.MergeArea
                Debug.Print i.Address
                TabAdress(cpt) = i.Address(0, 0)
                If cpt <> Rgn.MergeArea.Count Then cpt = cpt + 1: ReDim Preserve TabAdress(1 To cpt)
            Next i
        End If
Rgn(0, 1).Resize(LBound(TabAdress), UBound(TabAdress)) = TabAdress
End Sub

 

[Staple1600]

Bonsoir le fil

=>laurent950
Biaisons en attendant que la soupe refroidisse

Sub Test_II()
j = 8: Set r = Range([ZAZA].MergeArea.Address(0, 0))
For Each c In r: Cells([ZAZA].Item(1).Row - 1, j) = c.Address(0, 0): j = j + 1: Next
End Sub

 

[Magic_Doctor]

Re,

Bonsoir Staple1600,

Je viens d'essayer votre dernier post. Ça plante.
Pourquoi pas un exemple en PJ.